Exemplos de Superfícies Usando pm3d
set xlabel "x"
set ylabel "y"
set key top
set border 4095
set xrange [-15:15]
set yrange [-15:15]
set zrange [-0.25:1]
set samples 25
set isosamples 20
set title "pm3d demo. Radial sinc function. Default options."
set pm3d; set palette
#show pm3d
#show palette
splot sin(sqrt(x**2+y**2))/sqrt(x**2+y**2)
set title "pm3d at s (surface) / ticslevel 0"
set ticslevel 0
set pm3d at s
set cblabel "colour gradient"
replot
set title "set pm3d solid; the surface hides part of border, tics and labels"
set pm3d solid
replot
set pm3d transparent
set title "pm3d at b (bottom)"
set pm3d at b
replot
set title "unset surface; set pm3d at st (surface and top)"
unset surface
set pm3d at st solid
replot
unset cblabel
set title "set pm3d at bstbst (funny combination, only for screen or postscript)"
set view 50,50
set pm3d at bstbst
replot
set pm3d transparent
set title "gray map"
set pm3d map
set palette gray
set samples 100; set isosamples 100
replot
set title "gray map, negative"
set pm3d map
set palette gray negative
replot
set title "colour map, using default rgbformulae 7,5,15 ... traditional pm3d (black-blue-red-yellow)"
set palette color positive
set pm3d map
set samples 50; set isosamples 50
replot
set title "colour, rgbformulae 3,11,6 ... green-red-violet"
set palette rgbformulae 3,11,6
replot
set title "colour, rgbformulae 23,28,3 ... ocean (green-blue-white); OK are also all other permutations"
set palette rgbformulae 23,28,3
replot
set title "colour, rgbformulae 30,31,32 ... color printable on gray (black-blue-violet-yellow-white)"
set palette rgbformulae 30,31,32
replot
set title "rgbformulae 31,-11,32: negative formula number=inverted color"
set palette rgbformulae 31,-11,32
replot
set yrange [*:*] noreverse
reset
set title "surface at view 130,10 (viewed from below)"
set pm3d
set palette
set view 130,10
set samples 50; set isosamples 50
set border 4095
unset surface
set pm3d at s scansforward
splot sin(sqrt(x**2+y**2))/sqrt(x**2+y**2)
set title '"set pm3d scansbackward" makes this as viewed from above'
set xlabel
set border 4095
set pm3d scansbackward
replot
set title "set hidden3d"
set samples 30; set isosamples 30
set hidden3d
set pm3d
set surface
set view 50,220
set xrange [-2:2]
set yrange [-2:2]
splot log(x*x*y*y)
unset hidden3d
# draw the surface using pm3d's hidden3d with line type 100
unset hidden
unset surface
set title "set pm3d hidden3d <linetype>: pm3d's much faster hidden3d variant"
set samples 30; set isosamples 30
set pm3d
set style line 100 lt 5 lw 0.5
set pm3d solid hidden3d 100
set view 50,220
set xrange [-2:2]
set yrange [-2:2]
splot log(x*x*y*y)
set pm3d nohidden3d
set title "bad: surface and top are too close together"
set xrange [-1:1]
set yrange [-1:1]
unset hidd
set zrange [-15:4]
set ticslevel 0
set pm3d at st
splot log(x*x*y*y)
set title "solution: use independent 'set zrange' and 'set cbrange'"
unset surf
set cbrange [-15:4]
set zrange [-15:60]
splot log(x*x*y*y)
set autoscale cb
set title "color box is on by default at a certain position"
set samples 20; set isosamples 20
set autoscale
set key on
set pm3d
set pm3d at s
set view 60,30
splot y
set title "color box is on again, now with horizontal gradient"
set size 0.6,0.6; set origin 0.2,0.25
set colorbox horizontal
set colorbox user origin 0.1,0.15 size 0.8,0.1
set mcbtics 2
set grid cb
set cblabel "see cblabel, grid cb, mcbtics, ..."
replot
unset cblabel; unset mcbtics; set grid nocb; set colorbox default
set title "color box is switched off"
unset colorbox
replot
set title 'using now "set pm3d solid; set grid back; unset colorbox"'
unset colorbox
set pm3d solid
set border 895
set grid back
replot
set size 1,1; set origin 0,0
set grid layerdefault
set xlabel "X LABEL"
set ylabel "Y LABEL"
set sample 11; set isosamples 11
set pm3d map
set palette
set colorbox
set lmargin 0
set pm3d flush begin
set title "Datafile with different nb of points in scans; pm3d flush begin"
set pm3d flush begin noftriangles scansforward
splot 'triangle.dat'
#show pm3d
set title "Datafile with different nb of points in scans; pm3d flush center"
set pm3d flush center scansforward
replot
set title "Datafile with different nb of points in scans; pm3d flush end"
set pm3d flush end scansforward
replot
set grid front
set pm3d flush begin
set title "Data with different nb of points in scans; pm3d ftriangles flush begin"
set pm3d flush begin ftriangles scansforward
splot 'triangle.dat'
#show pm3d
set title "Data with different nb of points in scans; pm3d ftriangles flush center"
set pm3d flush center ftriangles scansforward
replot
set title "Data with different nb of points in scans; pm3d ftriangles flush end"
set pm3d flush end ftriangles scansforward
replot
reset
set title "only for enhanced terminals: 'set format cb ...'"
set xlabel "X"
set ylabel "Y"
set sample 31; set isosamples 31
set xrange [-185:185]
set yrange [-185:185]
set format cb "%.01t*10^{%T}"
unset surface
set border 4095
set ticslevel 0
set pm3d at s solid; set palette gray
set cblabel "the colour gradient"
splot abs(x)**3+abs(y)**3
unset cblabel
set pal color
set xrange [*:*]; set yrange [*:*]
set title "function 'x+y' using all colors available, 'set pal maxcolors 0'"
set pal maxcolors 0
splot x+y
set xrange [*:*]; set yrange [*:*]
set title "function 'x+y' using only 5 colors, 'set pal maxcolors 5'"
set pal maxcolors 5
splot x+y
set pal maxcolors 0
unset pm3d
set surface
set format z
set palette
set title "color lines: 'splot sin(y)/(y) with linespoints palette'"
set ticslevel 0
set border 4095
set xrange [-10:10]; set yrange [-10:10]
set hidden3d
set isosamples 40,40; set samples 40,40
splot sin(y)/(y) w lp palette
reset
set title "Demo for clipping of 2 rectangles comes now. The xrange is [0:2]..."
set pm3d; set palette
set pm3d map
set xrange [0:2]
splot 'clip14in.dat'
set xrange [0:1.5]
set yrange [*:*]
set title "...and now xrange is [0:1.5] and 'set pm3d clip1in'"
set pm3d clip1in
replot
set title "...now xrange is [0:1.5] and 'set pm3d clip4in'"
set pm3d clip4in
replot
reset
sinc(u,v) = sin(sqrt(u**2+v**2)) /sqrt(u**2+v**2)
set sam 40
set iso 40
set title "pm3d explicit mode --- coloring according to the 4th parameter of 'using'"
set ticslevel 0
set pm3d at s explicit solid
# 'binary2' binary u 1:2:(column(3)+column(-1)/20.0):3 w pm3d,
splot \
'binary2' binary u 1:2:3:($2+($1+$2)/10) w pm3d, \
1+sinc(x*4, y*4) w l
set title "coloring according to the 3rd 'using' parameter (left) and to the z-value (bottom)"
set border 895
splot \
'binary2' binary u 2:(12 - column(3) * 10):1 notitle w lines, \
'binary2' binary u (-12 + column(3) * 10):2:1:(-12 + column(3) * 10) notitle w pm3d, \
'binary2' binary u 1:2:(column(3) * 10 - 12) notitle w pm3d