;;---------------------------------
;; Shitlist 2.0 - by diffusi0n
;;---------------------------------

on *:load: {
  echo -a 2*** Shitlist 2.0 by diffusi0n loaded!
  echo -a 2*** Command for use: /shitlist
  .set %st.msg Shitlisted!
  .set %st.status off
  .set %st.reason kb
}

alias shitlist { dialog -m shitlist shitlist }
dialog shitlist {
  title "Shitlist 2.0 - coded by diffusi0n"
  size -1 -1 348 244
  box "Config", 1, 6 5 336 231
  box "List", 2, 16 21 151 154
  list 3, 26 39 130 125, size sorted
  box "Options", 4, 170 21 162 81
  text "Nick:", 5, 179 47 30 13
  edit "", 6, 212 39 109 22, multi return autohs
  button "ADD", 7, 183 68 65 23
  button "REM", 8, 252 68 65 23
  box "Status", 10, 171 102 81 73
  radio "On", 11, 180 119 60 23, push group
  radio "Off", 12, 180 143 60 23, push
  box "Reason", 13, 254 102 78 56
  radio "Kick", 14, 262 120 51 13, group
  radio "Kick/Ban", 15, 262 136 64 13
  text "S h i t l i s t", 16, 267 160 60 13, disabled
  box "Message", 17, 16 175 235 49
  edit "", 18, 26 192 214 22, multi return autohs
  button "Exit", 19, 262 191 65 23, ok
}
on *:dialog:shitlist:*:*: {
  if $devent = init {
    didtok shitlist 3 32 %st.list 
    did -a shitlist 18 %st.msg
    if (%st.status == on) { did -c shitlist 11 }
    elseif (%st.status == off) { did -c shitlist 12 }
    if (%st.reason == k) { did -c shitlist 14 }
    elseif (%st.reason = kb) { did -c shitlist 15 }
  }
  if $devent = sclick { 
    if $did = 7 { if ($did(6).text == $null) { return } | else { did -a shitlist 3 $did(6).text | set %st.list $didtok(shitlist,3,32) | .auser 3 $did(6).text | did -r shitlist 6 } }
    if $did = 8 { if ($did(3).sel == $null) { return } | else { .ruser $did(3,$did(3).sel).text | did -d shitlist 3 $did(3).sel | set %st.list $didtok(shitlist,3,32) } }
    if $did = 11 { .set %st.status on | .enable #shitlist }
    if $did = 12 { .set %st.status off | .disable #shitlist }
    if $did = 14 { .set %st.reason k }
    if $did = 15 { .set %st.reason kb }
  }
  if $devent = edit {
    if $did = 18 { .set %st.msg $did(18) }
  }
}

#shitlist on
on 3:join:#: { if ($me isop $chan) { if (%st.reason == k) { kick $chan $nick %st.msg } | elseif (%st.reason == kb) { ban $chan $nick 3 | kick $chan $nick %st.msg } } }
#shitlist end

alias st.about { dialog -m st.about st.about }
dialog st.about {
  title "About.."
  size -1 -1 156 114
  box "Shitlist 2.0", 1, 10 7 140 11
  text "Author: diffusi0n", 2, 11 29 83 13
  text "Released: 04/01/2002", 3, 11 49 116 13
  list 4, -24 71 202 6, size
  button "Exit", 5, 43 84 65 23, ok
}

alias shitlist.unload { echo -a 2*** Addon unloaded! | .unload -rs $scriptdirshitlist20.mrc }

menu status,channel,menubar {
  Shitlist 2.0
  .Config:shitlist
  .-
  .About:st.about
  .Readme:run readme.txt
  .-
  .Unload:shitlist.unload
}

