xecho -b -c Url Grabber script loaded!
xecho -b -c by gircobain 26/12/2002

assign URL_GRABBER 1
assign URL_VERBOSE 1

# file to save your url's
assign URL_FILE ~/TekNap.url

# path to your favorite browsers
assign HTTPBROWSER C:\Arquivos de programas\Internet Explorer\IEXPLORE.EXE
assign FTPBROWSER D:\Arquivos de programas\FlashFXP\flashfxp.exe

assign URL_NUMBER 0
assign URL_PREFIX http:// ftp:// www. ftp.

@delarray(url)
if (URL_GRAB == [ON]) ^set URL_GRAB OFF
xecho -b -c Improved URL grab [ On]

alias _make_launch {
  if (fexist(//c/launch.bat) == 1) @unlink(//c/launch.bat)
  @:fd = open(//c/launch.bat w)
  @write($fd \@echo off)
  @write($fd $*)
  @write($fd del c:\launch.bat)
  @close($fd)
}

on #-public 1716 '% %* \\[${URL_PREFIX}\\]*' if (URL_GRABBER) {
  ^local url, prefix
  fe ($URL_PREFIX) prefix {
    @:pos = match($prefix* $2-)
    if (pos) {
      @url = word(${pos-1} $2-)
      break
    }
  }
  if (matchitem(url % % % $url) < 0 && url != []) if (URL_GRABBER) {
    if (numitems(url) => MAX_URLS) @delitem(url 0)
    @setitem(url $numitems(url) $-1 -- $url)
    @URL_NUMBER++
    if (URL_VERBOSE) xecho -b -c Added HTTP/FTP grab [$numitems(url)/$URL_NUMBER]
  }
}

on #-msg 2784 '%* \\[${URL_PREFIX}\\]*' if (URL_GRABBER) {
  ^local url, prefix
  fe ($URL_PREFIX) prefix { 
    @:pos = match($prefix* $1-)
    if (pos) {
      @url = word(${pos-1} $1-)
      break
    }
  }
  if (matchitem(url % % % $url) < 0 && url != []) {
    if (numitems(url) => MAX_URLS) @delitem(url 0)
    @setitem(url $numitems(url) $0 \(msg\) -- $url)
    @URL_NUMBER++
    if (URL_VERBOSE) xecho -b -c Added HTTP/FTP grab [$numitems(url)/$URL_NUMBER]
  }
}

alias url {
  ^local from, to
  switch ($0) {
    (on) {
      ^assign URL_GRABBER 1
      xecho -b -c Improved URL grab [ On]
    }
    (off) {
      ^assign URL_GRABBER 0
      xecho -b -c Improved URL grab [Off]
    }
    (list) (+) {
      if (numitems(url)) {
        if (match(*-* $1)) {
          @from = before(- $1)
          @to = after(- $1)
          if (from == []) @from = 1
          if (to == []) @to = numitems(url)
        }{
          if ([$1] == []) {
            @from = 1
            @to = numitems(url)
          }{
            @from = to = [$1]
          }
        }
        if (from != from * 1 || to != to * 1) {
          xecho -b -c Invalid values
          return
        }
        if (to < from || from < 1 || from > numitems(url) || to < 1 || to > numitems(url)) {
          xecho -b -c Invalid values
          return
        }
        for (@:count = from - 1 , count < to, @count++) {
          xecho -c URL[$(\[${0 - @MAX_URLS}\]{count+1})] $getitem(url $count)
        }
      }{
        xecho -b -c No Urls in Url list
      }
    }
    (save) {
      @:fd = open($URL_FILE w)
      while (numitems(url)) {
        @write($fd $getitem(url 0))
        @delitem(url 0)
      }
      @close($fd)
      xecho -b -c Url list saved to $URL_FILE
    }
    (-) {
      if (match(*-* $1)) {
        @:from = before(- $1)
        @:to = after(- $1)
        if (from == []) @from = 1
        if (to == []) @to = numitems(url)
      }{
        if ([$1] == []) {
          @from = 1
          @to = numitems(url)
        }{
          @from = to = [$1]
        }
      }
      if (from != from * 1 || to != to * 1) {
        xecho -b -c Invalid values
        return
      }
      if (to < from || from < 1 || from > numitems(url) || to < 1 || to > numitems(url)) {
        xecho -b -c Invalid values
        return
      }
      repeat ${1 + to - from} @delitem(url ${from - 1})
      xecho -b -c Cleared Url \[${!(from ^^ to) ? from:}-${!(from ^^ to) ? to:}\]
    }
    (goto) {
      if ([$1] < 1 || [$1] > numitems(url)) {
        xecho -b -c Invalid value
        return
      }
      @:pos = [$1]
      @:url = rightw(1 $getitem(url ${pos-1}))
      if (match(ftp* $url)) {
        _make_launch "$FTPBROWSER" "$url"
      }{    
        _make_launch "$HTTPBROWSER" "$url"
      }
      exec -name URL$pos c:/launch.bat
      if (URL_VERBOSE) xecho -b -c Launching Url \[$url\]
      ^on ^exec_exit 'URL$pos *' on exec_exit -'URL$pos *'
    }
  }
}