CALCULO DE INDICADORES DE PROYECTOS DE INVERSIÓN CON EXCEL

Para preparar un proyecto de inversión se deben pasar por las distintas etapas:idea,preinversión, inversión y operación.

A su vez la etapa de preinversión implica seguir los pasos sucesivos de estudios de nivel perfil, prefactibilidad y factibilidad.

Idea Preinversión Inversión Operación Perfil Prefactibilidad Factibilidad

Para llevar a cabo un proyecto de inversión, son necesarios varios estudios técnicos: de mercado, técnico, organizacional, legal y financiero.

Precisamente es en este último en donde se resume toda la información obtenida a través de

los otros estudios, que sirve para elaborar flujos de fondos sobre los cuales se calcularán los

distintos indicadores de su rentabilidad.

En este sentido, Microsoft Excel permite la realización del trabajo con muchas facilidades.

La metodología se explicará a través de la resolución de un caso práctico, que consistirá en la construcción de flujos de fondos y obtención de los indicadores de rentabilidad Tasa Interna de

Retorno (TIR), Valor Actual Neto (VAN), Período de Recuperación de la Inversión (PRI) y Período de Recuperación de la Inversión Descontado (PRI Descontado).

Principales Conceptos

VAN

• El Valor Actual Neto surge de sumar los flujos de fondos actualizados de un proyecto de

   inversión.

• Mide la riqueza que aporta el proyecto medida en moneda del momento inicial.

• Para actualizar los flujos de fondos, se utiliza la tasa de descuento.

• La regla de decisión es la siguiente:

o Aceptar los proyectos con VAN>0

o Rechazar los proyectos con VAN<0

o Es indiferente aceptar o rechazar los proyectos con VAN=0

• Entre dos proyectos alternativos, se debe seleccionar el que tenga mayor VAN

• Existe un único VAN para cada proyecto

• Considera todos los flujos de fondos del proyecto.

• Considera los flujos de fondos adecuadamente descontados.

• Mide la rentabilidad en términos monetarios.

TIR

• Son todas aquellas tasas que hacen que el VAN=0.

• Considera todos los flujos de fondos del proyecto.

• Considera los flujos de fondos adecuadamente descontados.

• La regla de decisión es la siguiente:

o Aceptar los proyectos con TIR>r, siendo r la tasa de corte previamente definida.

• Puede existir más de una TIR por cada proyecto, dependiendo del comportamiento de los

   flujos de fondo.

• Existirá una única TIR para un proyecto cuando éste se considere bien comportado, o sea

  que haya un único cambio de signo de los flujos de fondos.

• Mide la rentabilidad en términos porcentuales.

PRI

• Se interpreta como el tiempo necesario para que el proyecto recupere el capital invertido.

• Mide la rentabilidad en términos de tiempo.

• No considera todos los flujos de fondos del proyecto, ya que ignora aquellos que se

   producen con posterioridad al plazo de recuperación de la inversión.

• No permite jerarquizar proyectos alternativos.

• No considera los flujos de fondos adecuadamente descontados.

• La regla de decisión es la siguiente:

o Aceptar los proyectos con PRI<p, siendo p el plazo máximo de corte previamente

   definido.

PRI Descontado

• Considera los flujos de fondos adecuadamente descontados.

• Mantiene las demás características del PRI.

Caso práctico

Para explicar la metodología a utilizar, se resolverá el siguiente caso:

Suponga la existencia de un proyecto de inversión de 5 años de duración.

En este período, los ingresos por ventas anuales serán de $60.000, los costos fijos anuales de $10.000 y los costos variables se estiman como un 45% de los ingresos por ventas.

Para lograrlo, será necesario concretar inversiones en activo fijo por $40.000 amortizables linealmente en 5 años de plazo; se estima que estas inversiones tendrán un valor residual  nulo al cabo de 5 años.

También será necesaria una inversión en activo de trabajo de $5.000, que será recuperable en un 100% al término de los 5 años.

Considerar que la tasa de impuestos es de un 30% y la tasa de descuento es del 15%. El inversor puede acceder a un préstamo bancario de $20.000 a reintegrar en 5 cuotas anuales con un interés del 12% anual, calculadas con sistema de amortización alemán.

Solución

Para resolver este caso, vamos a desarrollar en este orden:

1) Flujo de fondos del proyecto

2) Flujo de fondos del préstamo

3) Flujo de fondos del inversionista

A partir de ellos, se obtendrán los distintos indicadores.

Primeramente, se debe crear un nuevo libro de Microsoft Excel, cuyo contenido se propone en este trabajo.

Para una mejor identificación visual, las celdas que contienen entradas de datos independientes se presentan con fuente blanca y fondo negro (presentación tipo video invertido).

Las celdas que presentan fórmulas con valores dependientes (o sea que contienen una fórmula porque sus valores dependen de otras celdas), se presentan con fuente negra y fondo  blanco (que es la presentación normal). El primer dato que vamos a ingresar es la  asa de descuento, cuyo valor es del 15%:
[image: image1.png]A B

C

1 [TASA DE DESCUENTO




Flujo de Fondos del Proyecto

Construcción

En base a los datos del caso práctico, se construye el flujo de fondos del proyecto:

Contenido de las celdas

E6. =60000

Se ingresa el monto estimado de las ventas anuales.

F6. =E6

G6. =F6

H6. =G6

I6. =H6

El valor se repite todos los años

E7. =10000

Se ingresa el monto de los costos fijos.

F7. =E7

G7. =F7

H7. =G7

I7. =H7

El valor se repite todos los años

C8. =45%

Se ingresa el porcentaje de costo variable.

E8. =E6*$C8

F8. =F6*$C8

G8. =G6*$C8

H8. =H6*$C8

I8. =I6*$C8

Se calcula el costo variable como un porcentaje del monto de ventas.

E9. =8000

Se ingresa el monto anual de la amortización calculada linealmente como =40000/5

F9. =E9

G9. =F9

H9. =G9

I9. =H9

El valor se repite todos los años

E10. =E6-E7-E8-E9

F10. =F6-F7-F8-F9

G10. =G6-G7-G8-G9

H10. =H6-H7-H8-H9

I10. =I6-I7-I8-I9

Se calcula el subtotal antes de impuestos

C11. =30%

Se ingresa el porcentaje de impuestos a aplicar sobre el flujo de fondos antes de impuestos.

E11. =SI(SUMA($E10:E10)>0;SUMA($E10:E10)*$C11;0)

F11. =SI(SUMA($E10:F10)*$C11-SUMA($E11:E11)>0;SUMA($E10:F10)*$C11-

SUMA($E11:E11);0)

G11. =SI(SUMA($E10:G10)*$C11-SUMA($E11:F11)>0;SUMA($E10:G10)*$C11-

SUMA($E11:F11);0)

H11. =SI(SUMA($E10:H10)*$C11-SUMA($E11:G11)>0;SUMA($E10:H10)*$C11-

SUMA($E11:G11);0)

I11. =SI(SUMA($E10:I10)*$C11-SUMA($E11:H11)>0;SUMA($E10:I10)*$C11-

SUMA($E11:H11);0)

Se calcula el importe del impuesto. La función prevé el caso en que el flujo de fondos antes de impuestos sea negativo, en cuyo caso no se perciben impuestos y la pérdida de ese ejercicio sirve para disminuir la base imponible del ejercicio siguiente. Concretamente, - se suman los flujos de fondos desde el inicio hasta el ejercicio actual y se calcula el impuesto

- se suman los flujos de fondos desde el inicio hasta el ejercicio anterior y se calcula el  impuesto

- si el resultado es mayor que 0 se consigna como impuesto la diferencia, caso contrario se consigna 0

E12. =E10-E11

F12. =F10-F11

G12. =G10-G11

H12. =H10-H11

I12. =I10-I11

Se obtiene el flujo de fondos después de impuestos.

E13. =E9

F13. =F9

G13. =G9

H13. =H9

I13. =I9

Se consignan las amortizaciones con signo invertido, dado que no son erogaciones de dinero y sólo fueron incluidas al efecto de disminuir la base imponible del impuesto.

D14. =40000

El monto de la inversión en activo fijo.

D15. =5000

El monto de la inversión en activo de trabajo.

I17. =D15

Porque el activo de trabajo se recupera en un 100% al final del proyecto.

D18. =D12+D13-D14-D15+D16+D17

E18. =E12+E13-E14-E15+E16+E17

F18. =F12+F13-F14-F15+F16+F17

G18. =G12+G13-G14-G15+G16+G17

H18. =H12+H13-H14-H15+H16+H17

I18. =I12+I13-I14-I15+I16+I17

Se calcula el flujo de fondos del proyecto

D19. =VA($D$1;D$5;;-D18)

E19. =VA($D$1;E$5;;-E18)

F19. =VA($D$1;F$5;;-F18)

G19. =VA($D$1;G$5;;-G18)

H19. =VA($D$1;H$5;;-H18)

I19. =VA($D$1;I$5;;-I18)

Se calcula el valor actual de cada uno de los flujos, utilizando la tasa de descuento.

Cálculo de indicadores

A continuación, la forma de calcular los indicadores más utilizados:

Contenido de las celdas

C21. =TIR(C18:I18)

Se calcula la Tasa Interna de Retorno en base al rango de datos del flujo de fondos completo (se

incluye el período inicial o 0).

A22. ="VAN "&TEXTO($D$1;"0.00%")

Es una fórmula especial para que la celda muestre la palabra VAN y a continuación la tasa de descuento que se haya ingresado en la celda D1. Ante cualquier cambio en esta última celda, se modificará la etiqueta de la celda.

C22. =VNA($D$1;E18:I18)+D18

Se calcula el Valor Actual Neto en dos tiempos:

Primero: se calcula el Valor Neto Actualizado sobre el rango que va desde el período 1 hasta el período 5; NO se incluye el período inicial.

Segundo: al resultado calculado en el punto primero se le agrega el flujo de fondos del período inicial. Esto es así porque VNA no es lo mismo que VAN

C23. =MIN(D23:I23)

Calcula el Período de Recuperación de la Inversión sobre el flujo de fondos nominal, informando el primer período en que la suma acumulada de flujos de fondos desde el inicio en adelante toma un valor positivo (allí se recupera la inversión)

D23. =SI(SUMA($D18:D18)>0;D$5;"")

E23. =SI(SUMA($D18:E18)>0;E$5;"")

F23. =SI(SUMA($D18:F18)>0;F$5;"")

G23. =SI(SUMA($D18:G18)>0;G$5;"")

H23. =SI(SUMA($D18:H18)>0;H$5;"")

I23. =SI(SUMA($D18:I18)>0;I$5;"")

Estas funciones ayudan a detectar el momento en que la suma acumulada de flujos de fondos desde el inicio en adelante toma un valor positivo. Para evitar que el resultado en estas celdas sea visible, se asigna a las celdas un formato personalizado que oculta la información contenida en ellas:

C24. =MIN(D24:I24)

Calcula el Período de Recuperación de la Inversión sobre el flujo de fondos descontado, informando

el primer período en que la suma acumulada de flujos de fondos desde el inicio en adelante toma un valor positivo (allí se recupera la inversión)

D24. =SI(SUMA($D19:D19)>0;D$5;"")

E24. =SI(SUMA($D19:E19)>0;E$5;"")

F24. =SI(SUMA($D19:F19)>0;F$5;"")

G24. =SI(SUMA($D19:G19)>0;G$5;"")

H24. =SI(SUMA($D19:H19)>0;H$5;"")

I24. =SI(SUMA($D19:I19)>0;I$5;"")

Estas funciones ayudan a detectar el momento en que la suma acumulada de flujos de fondos descontados desde el inicio en adelante toma un valor positivo.

Análisis del Préstamo Bancario
Construcción

De acuerdo al temario, el préstamo debe reintegrarse por sistema de amortización alemán.

Recordemos que la característica de este tipo de préstamos es que el capital de las cuotas es

constante, mientras que el interés de cada cuota es decreciente, porque se calcula sobre el saldo impago de capital.

El desarrollo es entonces el siguiente:

Contenido de las celdas

B3. =20000

Se ingresa el importe del préstamo

B4. =5

Se ingresa la cantidad de cuotas en que debe ser reintegrado.

B5. =12%

Se ingresa la tasa de interés anual del préstamo

D7. =B3

E7. =D7

Se ingresa el importe recibido.

F7. =E7-E8

G7. =F7-F8

H7. =G7-G8

I7. =H7-H8

Saldo del préstamo antes de efectuar el pago. Se calcula como el saldo al inicio del período anterior menos el pago de capital realizado durante el período anterior.

E8. =SI(E2>$B$4;0;$B$3/$B$4)

F8. =SI(F2>$B$4;0;$B$3/$B$4)

G8. =SI(G2>$B$4;0;$B$3/$B$4)

H8. =SI(H2>$B$4;0;$B$3/$B$4)

I8. =SI(I2>$B$4;0;$B$3/$B$4)

Calcula el componente de capital de cada cuota. En principio cada cuota es igual a =20000/5. Dada la posibilidad que el plazo de pago del préstamo sea menor que la vida del proyecto, la fórmula prevee consignar el número 0 en aquellos períodos en que no corresponda realizar pago alguno.

E9. =E7*$B$5

F9. =F7*$B$5

G9. =G7*$B$5

H9. =H7*$B$5

I9. =I7*$B$5

Calcula el componente de interés de cada cuota. Se calcula como el saldo de capital antes de realizar el pago multiplicado por la tasa de interés anual definida.

E10. =SUMA(E8:E9)

F10. =SUMA(F8:F9)

G10. =SUMA(G8:G9)

H10. =SUMA(H8:H9)

I10. =SUMA(I8:I9)

Calcula el importe total de cada cuota, sumando los componentes de capital e interés.

Flujo de Fondos del Préstamo

Construcción

En base al análisis del préstamo realizado, se construye el flujo de fondos del préstamo:

Contenido de las celdas

E29. =2400

F29. =1920

G29. =1440

H29. =960

I29. =480

Se ingresan los pagos de intereses, obtenidos del análisis del préstamo,

D30. =-D29

E30. =-E29

F30. =-F29

G30. =-G29

H30. =-H29

I30. =-I29

Se obtiene el flujo de fondos de la financiación antes de impuestos

C31. =C11

Copia la tasa de impuestos que fuera anteriormente cargada.

E31. =-E30*$C$31

F31. =-F30*$C$31

G31. =-G30*$C$31

H31. =-H30*$C$31

I31. =-I30*$C$31

Calcula el impuesto, definido como el flujo de fondos de la financiación antes de impuestos

multiplicado por la tasa de impuestos.

E32. =E30+E31

F32. =F30+F31

G32. =G30+G31

H32. =H30+H31

I32. =I30+I31

Se obtiene el flujo de fondos de la financiación después de impuestos.

D33. =20000

Se ingresa el monto del préstamo recibido.

D34. = 4000

E34. = 4000

F34. = 4000

G34. = 4000

H34. = 4000

I34. = 4000

Se ingresan los pagos de capital, obtenidos del análisis del préstamo,

D35. =D32+D33-D34

E35. =E32+E33-E34

F35. =F32+F33-F34

G35. =G32+G33-G34

H35. =H32+H33-H34

I35. =I32+I33-I34

Se obtiene el flujo de fondos de la financiación.

Flujo de Fondos del Inversionista

Construcción

El flujo de fondos del inversionista resulta de sumar el flujo de fondos del proyecto y el flujo de

fondos de la financiación:

Contenido de las celdas

D40. =D18

E40. =E18

F40. =F18

G40. =G18

H40. =H18

I40. =I18

Copia los flujos de fondos del proyecto.

D41. =D35

E41. =E35

F41. =F35

G41. =G35

H41. =H35

I41. =I35

Copia los flujos de fondos de la financiación

D42. =D40+D41

E42. =E40+E41

F42. =F40+F41

G42. =G40+G41

H42. =H40+H41

I42. =I40+I41

Suma los flujos de fondos del proyecto y los flujos de fondos de la financiación.

D43. =VA($D$1;D$5;;-D42)

E43. =VA($D$1;E$5;;-E42)

F43. =VA($D$1;F$5;;-F42)

G43. =VA($D$1;G$5;;-G42)

H43. =VA($D$1;H$5;;-H42)

I43. =VA($D$1;I$5;;-I42)

Se calcula el valor actual de cada uno de los flujos, utilizando la tasa de descuento.

Cálculo de indicadores

Se calculan los indicadores más utilizados en el análisis de proyectos de inversión:
Contenido de las celdas

C45. =TIR(C42:I42)

Se calcula la Tasa Interna de Retorno en base al rango de datos del flujo de fondos completo (se

incluye el período inicial o 0).

C46. =VNA($D$1;E42:I42)+D42

Se calcula el Valor Actual Neto en dos partes:

Primero: se calcula el Valor Neto Actualizado sobre el rango que va desde el período 1 hasta el período 5; NO se incluye el período inicial.

Segundo: al resultado calculado en el punto primero se le agrega el flujo de fondos del período inicial.

Esto es así porque VNA no es lo mismo que VAN

C47. =MIN(D47:I47)

Calcula el Período de Recuperación de la Inversión sobre el flujo de fondos nominal, informando el primer período en que la suma acumulada de flujos de fondos desde el inicio en adelante toma un valor positivo (allí se recupera la inversión)

D47. =SI(SUMA($D42:D42)>0;D$5;"")

E47. =SI(SUMA($D42:E42)>0;E$5;"")

F47. =SI(SUMA($D42:F42)>0;F$5;"")

G47. =SI(SUMA($D42:G42)>0;G$5;"")

H47. =SI(SUMA($D42:H42)>0;H$5;"")

I47. =SI(SUMA($D42:I42)>0;I$5;"")

Estas funciones ayudan a detectar el momento en que la suma acumulada de flujos de fondos desde el inicio en adelante toma un valor positivo.

Para evitar que el resultado en estas celdas sea visible, se asigna a las celdas un formato personalizado que oculta la información contenida en ellas:

C48. =MIN(D48:I48)

Calcula el Período de Recuperación de la Inversión sobre el flujo de fondos descontado, informando el primer período en que la suma acumulada de flujos de fondos desde el inicio en adelante toma un valor positivo (allí se recupera la inversión)

D48. =SI(SUMA($D43:D43)>0;D$5;"")

E48. =SI(SUMA($D43:E43)>0;E$5;"")

F48. =SI(SUMA($D43:F43)>0;F$5;"")

G48. =SI(SUMA($D43:G43)>0;G$5;"")

H48. =SI(SUMA($D43:H43)>0;H$5;"")

I48. =SI(SUMA($D43:I43)>0;I$5;"")

Estas funciones ayudan a detectar el momento en que la suma acumulada de flujos de fondos desde el inicio en adelante toma un valor positivo.

Análisis del efecto de la financiación

Es evidente que los indicadores del proyecto con y sin financiación adoptan valores  diferentes.

Cabe entonces reflexionar acerca de cuál ha sido el impacto que sobre los primeros ha  tenido el hecho de haber podido obtener financiación (y obviamente con las condiciones descriptas).

A continuación, se analizar la variación de cada uno:

Contenido de las celdas

C51. =+C45/C21

C52. =+C46/C22

C53. =+C47/C23

C54. =+C48/C24

Conclusiones

En base a los guarismos analizados, financieramente se considera viable concretar la inversión y tomar el préstamo para financiarla.
