Unas buenas opciones para deshabilitar ciertas propiedades de una MDB

Public Function EstablecerPropiedadesDeInicio()
    CambiarPropiedad "StartupForm", dbText, "MENÚ_DE_INICIO"        ' Menú que se abre al inicio
    CambiarPropiedad "StartupShowDBWindow", dbBoolean, False            ' NO Mostrar la base de datos
    CambiarPropiedad "StartupShowStatusBar", dbBoolean, True  ' Mostrar Barra de Estado
    CambiarPropiedad "AllowBuiltinToolbars", dbBoolean, False ' NO Permitir Barras de Herramientas Incorporadas
    CambiarPropiedad "AllowToolbarChanges", dbBoolean, False ' NO Permitir Cambios en las Barras de Herramientas
    CambiarPropiedad "AllowFullMenus", dbBoolean, True ' Permitir Menús Completos
    CambiarPropiedad "AllowBreakIntoCode", dbBoolean, False ' NO Permitir Ver Código
    CambiarPropiedad "AllowSpecialKeys", dbBoolean, False ' NO Permitir Teclas Especiales
    CambiarPropiedad "AllowBypassKey", dbBoolean, False ' ESTA ES LA QUE TIENES QUE DESACTIVAR para lo que quieres
End Function

Function CambiarPropiedad(strPropName As String, varPropType As Variant, varPropValue As Variant) As Integer
    Dim dbs As Database, prp As Property
    Const conPropNotFoundError = 3270

    Set dbs = CurrentDb
    On Error GoTo Change_Err
    dbs.Properties(strPropName) = varPropValue
    CambiarPropiedad = True

Change_Bye:
    Exit Function

Change_Err:
    If Err = conPropNotFoundError Then  ' Propiedad no encontrada.

Set prp = dbs.CreateProperty(strPropName, _
            varPropType, varPropValue)
        dbs.Properties.Append prp
        Resume Next
    Else
        ' Error desconocido.
        CambiarPropiedad = False
        Resume Change_Bye
    End If
End Function