Hace algunos días solicite una ayuda sobre como exportar a excel alguna
información.  Me suministraron un código en DAO y se me indico que se podía
pasar a ADO.


ESTA ES LA RESPUESTA CON ADO
============================
Sub ExportExcel()
    'Defino las variables de trabajo
    Dim sExcelFileName As String
    Dim sWorksheetName As String
    Dim sTableName As String
    Dim strSQL As String
    Dim conn As ADODB.Connection

    ' Datos por defecto
    sExcelFileName = App.Path & "\download\" & Format(Now, "yyyymmdd") & ".xls"
    sWorksheetName = "WorkSheet1"
    sTableName = "tblTemp"

    'Si el archivo excel existe, lo elimino
    If Dir(sExcelFileName) <> "" Then Kill sExcelFileName

    ' Creo una tabla nueva mediante la instrucción
    ' SELECT...INTO
    strSQL = "SELECT * INTO [Excel 8.0;DATABASE=" & sExcelFileName & _
    "].[" & sWorksheetName & "] FROM " & "[" & sTableName & "]"

    Set conn = New ADODB.Connection
    With conn
        .ConnectionString = gs_Conn
        .Open
        .Execute strSQL
        .Close
    End With

    ' Por último, cierro la base de datos
    Set conn = Nothing
End Sub