Como saber si un ejecutable está vargado en esos momentos?

RESPONDE BUHO
=============

'Esto a un modulo
Option Explicit
Const TH32CS_SNAPHEAPLIST = &H1
Const TH32CS_SNAPPROCESS = &H2
Const TH32CS_SNAPTHREAD = &H4
Const TH32CS_SNAPMODULE = &H8
Const TH32CS_SNAPALL = (TH32CS_SNAPHEAPLIST Or TH32CS_SNAPPROCESS Or TH32CS_SNAPTHREAD Or TH32CS_SNAPMODULE)
Const TH32CS_INHERIT = &H80000000
Const MAX_PATH As Integer = 260
Private Type PROCESSENTRY32
    dwSize As Long
    cntUsage As Long
    th32ProcessID As Long
    th32DefaultHeapID As Long
    th32ModuleID As Long
    cntThreads As Long
    th32ParentProcessID As Long
    pcPriClassBase As Long
    dwFlags As Long
    szExeFile As String * MAX_PATH
End Type

Private Declare Function CreateToolhelp32Snapshot Lib "Kernel32" (ByVal lFlags As Long, ByVal lProcessID As Long) As Long
Private Declare Function Process32First Lib "Kernel32" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Function Process32Next Lib "Kernel32" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Sub CloseHandle Lib "Kernel32" (ByVal hPass As Long)


Function BuscaEjecutableCargado(Nombre As String) As Boolean
  Dim ValorBolean As Boolean, R
    Dim hSnapShot As Long, uProcess As PROCESSENTRY32
  
    hSnapShot = CreateToolhelp32Snapshot(TH32CS_SNAPALL, 0&)
   
    uProcess.dwSize = Len(uProcess)
    R = Process32First(hSnapShot, uProcess)
   
  
    Do While R
     If UCase(Left$(uProcess.szExeFile, IIf(InStr(1, uProcess.szExeFile, Chr$(0)) > 0, InStr(1, uProcess.szExeFile, Chr$(0)) - 1, 0))) = UCase(Nombre) Then
      ValorBolean = True
      Exit Do
     End If
        R = Process32Next(hSnapShot, uProcess)
    Loop
    CloseHandle hSnapShot
    BuscaEjecutableCargado = ValorBolean
End Function



RESPONDE RUBEN VIGON:
=====================

Si se desea testaer si un programa ejecutable (EN RED) esta siendo
usado por alguien:

Private Function ArchivoEstaAbierto(ByVal Ruta As String) As Boolean
On Error GoTo HayErrores
Dim f As Integer
   f = FreeFile
   Open Ruta For Append As f
   Close f
   ArchivoEstaAbierto = False
   Exit Function
HayErrores:
   If Err.Number = 70 Then
      ArchivoEstaAbierto = True
   Else
      Err.Raise Err.Number
   End If
End Function