Tengo que documentar una base de datos bastante "liada".
El documentador me da toda la información DENTRO de cada objeto (tablas,
consultas, etc.) pero NO lo lista a seca!
He leido alguna vez que se podía listar estos objetos con un pequeño codigo.
alguien me podría ayudar ?

RESPONDE HAPPY
==============

Te mando una funcion para Access 2000 o superior y otra para Access 97 que
lista algunos de los objetos de la base de datos:

'Para Access 2000 o superior
Function ListarObjetosBD()
Dim obj As AccessObject

  Debug.Print "TABLAS"
  Debug.Print "------"
  For Each obj In CurrentData.AllTables
    If Left(obj.Name, 4) <> "Msys" Then
      Debug.Print " - " & obj.Name
    End If
  Next

  Debug.Print
  Debug.Print "CONSULTAS"
  Debug.Print "---------"
  For Each obj In CurrentData.AllQueries
    Debug.Print " - " & obj.Name
  Next

  Debug.Print
  Debug.Print "FORMULARIOS"
  Debug.Print "-----------"
  For Each obj In CurrentProject.AllForms
    Debug.Print " - " & obj.Name
  Next

  Debug.Print
  Debug.Print "INFORMES"
  Debug.Print "--------"
  For Each obj In CurrentProject.AllReports
    Debug.Print " - " & obj.Name
  Next

  Debug.Print
  Debug.Print "MACROS"
  Debug.Print "------"
  For Each obj In CurrentProject.AllMacros
    Debug.Print " - " & obj.Name
  Next

  Debug.Print
  Debug.Print "MÓDULOS"
  Debug.Print "-------"
  For Each obj In CurrentProject.AllModules
    Debug.Print " - " & obj.Name
  Next

End Function

'Para Access 97
Function ListarObjetosBD97()
Dim db As Database
Dim tdf As TableDef
Dim qry As QueryDef
Dim con As Container
Dim doc As Document

  Set db = CurrentDb

  Debug.Print "TABLAS"
  Debug.Print "------"
  For Each tdf In db.TableDefs
    If Left(tdf.Name, 4) <> "Msys" Then
      Debug.Print " - " & tdf.Name
    End If
  Next

  Debug.Print
  Debug.Print "CONSULTAS"
  Debug.Print "---------"
  For Each qry In db.QueryDefs
    If Left(qry.Name, 3) <> "~" Then
      Debug.Print " - " & qry.Name
    End If
  Next

  Debug.Print
  Debug.Print "FORMULARIOS"
  Debug.Print "-----------"
  Set con = db.Containers("Forms")
  For Each doc In con.Documents
    Debug.Print " - " & doc.Name
  Next doc

  Debug.Print
  Debug.Print "INFORMES"
  Debug.Print "--------"
  Set con = db.Containers("Reports")
  For Each doc In con.Documents
    Debug.Print " - " & doc.Name
  Next doc

  Debug.Print
  Debug.Print "MACROS"
  Debug.Print "------"
  Set con = db.Containers("Scripts")
  For Each doc In con.Documents
    Debug.Print " - " & doc.Name
  Next doc

  Debug.Print
  Debug.Print "MÓDULOS"
  Debug.Print "-------"
  Set con = db.Containers("Modules")
  For Each doc In con.Documents
    Debug.Print " - " & doc.Name
  Next doc

  Set tdf = Nothing
  Set qry = Nothing
  Set doc = Nothing
  Set con = Nothing
  Set db = Nothing

End Function

Espero que te sirva