es posible almacenar una matriz entera en un campo binary?
Y sino, en que tipo de datos, y como, podria almacenar matrizes (arrays)?
Entiendes mi pregunta?


RESPONDE RUBÉN VIGON
=====================

Claro! Mediante AppendChunk, GetChunk, Split y Join; para el siguiente
ejemplo he utilizado una base de datos de Access y un campo de tipo «Objeto
OLE» (que denominé «Array»); para SQL Server podrías utilizar un campo de
tipo «image»

Dim strArray(1 To 30) As String, i As Long, Cad As String, varArray
Dim Cn As ADODB.Connection, Rs As ADODB.Recordset
'--- Cargar el array: ABC01, ABC02,..., ABC30
For i = 1 To 30
    strArray(i) = "ABC" & Format$(i, "00")
Next i
'--- Abrir el Recordset y agregar un nuevo registro
Set Cn = New ADODB.Connection
Set Rs = New ADODB.Recordset
Cn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data
Source=C:\BaseDatos.mdb;Persist Security Info=False"
Rs.Open "NombreTabla", Cn, adOpenDynamic, adLockOptimistic, adCmdTable
Rs.AddNew
Rs.Fields("Array").AppendChunk Join(strArray, vbNullChar)
Rs.Update
'--- Mostrar el contenido del registro
Rs.MoveFirst
Cad = Rs.Fields("Array").GetChunk(Rs.Fields("Array").ActualSize)
varArray = Split(Cad, vbNullChar)
For i = LBound(varArray) To UBound(varArray)
    MsgBox varArray(i)
Next i
'--- Cerrar Recordset y conexión
Rs.Close: Set Rs = Nothing
Cn.Close: Set Cn = Nothing