1. Abrir una Base de Datos.

2. Crear un formulario en blanco que no esté basado en ninguna 
tabla o consulta, y poner las siguientes propiedades en el 
formulario:

Barras de desplazamiento: Ninguna.

Selectores de registro: No.

Botones de desplazamiento: No.

Al cronómetro: [Procedimiento de evento].

Intervalo de cronómetro: 0.

3. Añadir un cuadro de texto al formulario y poner las siguientes 
propiedades al cuadro de texto:

Nombre: Tiempo.

Valor predeterminado: "00:00:00:00".

Activado: No.

Bloqueado: Si.

4. Añadir un botón al formulario y poner las siguientes 
propiedades:

Nombre: BtnInicioParar.

Título: Inicio.

Al hacer clic: [Procedimiento de evento].

5. Añadir un segundo botón al formulario y poner las siguientes 
propiedades:

Nombre: BtnReiniciar.

Título: Reiniciar.

Al hacer clic: [Procedimiento de evento].

6. Añadir el siguiente código en la sección de declaraciones de un 
módulo del formulario:

Option Compare Database
Option Explicit
Dim TotalElapsedMilliSec As Long
Dim StartTickCount As Long

Private Declare Function GetTickCount Lib "kernel32" () As _
Long

7. Añadir el siguiente código en el evento Timer del formulario:

Private Sub Form_Timer()
Dim Horas As String
Dim Minutos As String
Dim Segundos As String
Dim MiliSeg As String
Dim Msg As String
Dim ElapsedMiliSeg As Long

ElapsedMiliSeg = (GetTickCount() - StartTickCount) + _
TotalElapsedMilliSec

Horas = Format((ElapsedMiliSeg \ 3600000), "00")
Minutos = Format((ElapsedMiliSeg \ 60000) Mod 60, "00")
Segundos = Format((ElapsedMiliSeg \ 1000) Mod 60, "00")
MiliSeg = Format((ElapsedMiliSeg Mod 1000) \ 10, "00")

Me!Tiempo = Horas & ":" & Minutos & ":" & Segundos & ":" _
& MiliSeg

End Sub

8. Añadir el siguiente código en el evento Clic del botón 
BtnInicioParar.

Private Sub BtnInicioParar_Click()
If Me.TimerInterval = 0 Then
StartTickCount = GetTickCount()
Me.TimerInterval = 15
Me!BtnInicioParar.Caption = "Parar"
Me!BtnReiniciar.Enabled = False
Else
TotalElapsedMilliSec = TotalElapsedMilliSec + _
(GetTickCount() - StartTickCount)
Me.TimerInterval = 0
Me!BtnInicioParar.Caption = "Iniciar"
Me!BtnReiniciar.Enabled = True
End If
End Sub

9. Añadir el siguiente código en el evento clic del botón 
BtnReiniciar:

TotalElapsedMilliSec = 0
Me!Tiempo = "00:00:00:00"

10. Abrir el formulario en vista formulario.