19999 END
20000 IF CL$="NOCHK" THEN 20100
20010 GOSUB 20060:REM INIT VARS
20040 GOSUB 24000:REM CHECK INTEGRITY
20050 GOTO 20110
20060 CLEAR:V$="0.30":W=3:DIM BA$(0)*64:J=0:GOSUB " ":S=A,E=A+B-1,CS=C
20070 GOSUB 21000:REM INTRO
20090 RETURN
20100 GOSUB 20060:REM INIT VARS
20110 GOSUB 25000:REM LOAD ML CODE
20120 GOSUB 26000:REM CALL FDISK AND EXEC NEW CMD
20130 END
20999 REM INTRO
21000 PAUSE "THIS PROGRAM"
21005 PAUSE "WILL INSTALL" 
21010 PAUSE "PSHELL ";V$;" ON" 
21015 PAUSE "YOUR POCKET"
21020 PAUSE "COMPUTER. CALL" 
21025 BEEP 1:WAIT:PRINT"ADDRESS IS ";STR$ (S+4)
21030 PAUSE "CAUTION: THIS" 
21035 PAUSE "PROCEDURE WILL" 
21040 PAUSE "CLEAR ALL MEMORY"
21045 PAUSE "OF YOUR POCKET"
21050 PAUSE "COMPUTER"
21060 INPUT "CONTINUE ? ";D$
21070 D$=LEFT$(D$,1):IF D$="Y" RETURN
21080 IF D$="N" END
21090 GOTO 21060
23999 REM CHECK INTEGRITY
24000 WAIT W:RESTORE " "
24010 A=0:PAUSE "CHECK INTEGRITY"
24020 P=0:GOSUB 30000:REM PROGRESS BAR 1
24030 FOR I=S TO E
24040 GOSUB 27000:A=A+B
24050 R=I-S,P=INT (15*R/(E-S))
24060 IF P=Q THEN 24090
24070 GOSUB 30000:REM PROGRESS BAR 1
24080 Q=P
24090 NEXT I:BEEP 1
24100 IF A=CS RETURN
24110 PAUSE "DATA ERROR: IF"
24115 PAUSE "YOU TYPED THE"
24120 PAUSE "PROGRAM, CHECK"
24125 PAUSE "FOR TYPO'S, IF"
24130 PAUSE "YOU LOADED IT,"
24135 PAUSE "TRY LOADING"
24140 WAIT:PRINT "AGAIN."
24150 END
24999 REM LOAD ML CODE
25000 WAIT W:RESTORE " "
25010 PAUSE "LOADING PSHELL"
25020 P=0:GOSUB 30100:REM PROGRESS BAR 2
25030 FOR I=S TO E
25040 GOSUB 27000:POKE I,B
25050 R=I-S,P=INT (15*R/(E-S))
25060 IF P=Q THEN 25090
25070 GOSUB 30100:REM PROGRESS BAR 2
25080 Q=P
25090 NEXT I:BEEP 1
25100 RETURN
25999 REM SWITCH TO PRO MODE AND EXECUTE NEW
26000 PAUSE "EXECUTE FDISK .."
26005 I=S:S$="FDISK":CALL I+16:CALL I+12
26010 S$="PROMODE":CALL I+16:POKE I,42:CALL I+12
26015 A=PEEK I:IF A THEN 26050
26020 PAUSE "ON BASIC PROMPT"
26025 PAUSE "CHANGE TO"
26030 PAUSE "PROGRAM MODE"
26035 WAIT:PRINT "AND TYPE NEW"
26040 END
26050 CALL I+12:NEW
26070 END
26998 REM THE READ ROUTINE
26999 REM USED VARS: BA$,J,K,L RETVAL: B
27000 IF J<=0 READ BA$(0):J=LEN BA$(0):K=1
27010 L=ASC MID$(BA$(0),K,1)
27020 IF L<58 LET L=L-48
27030 IF L>96 LET L=L-87
27040 B=16*L:L=ASC MID$(BA$(0),K+1,1)
27050 IF L<58 LET L=L-48
27060 IF L>96 LET L=L-87
27070 B=L+B:K=K+2:J=J-2:RETURN
29999 REM PROGRESS BAR 1
30000 Q=15-P:PRINT "":PRINT "":PRINT "CHECK INTEGRITY" 
30010 PRINT LEFT$("---------------",P);LEFT$("???????????????",Q)
30020 BEEP 1:RETURN
30099 REM PROGRESS BAR 2
30100 Q=15-P:PRINT "":PRINT "":PRINT "LOADING PSHELL"
30110 PRINT LEFT$("===============",P);LEFT$("---------------",Q)
30120 BEEP 1:RETURN
