REM Play Level 2-front war

REM ******* Basic settings *******

SET_GENERATE_SPEED(200)

MAX_CREATURES(PLAYER0,21)
MAX_CREATURES(PLAYER1,15)
MAX_CREATURES(PLAYER2,25)

START_MONEY(PLAYER0,25000)
START_MONEY(PLAYER1,25000)
START_MONEY(PLAYER2,25000)

COMPUTER_PLAYER(PLAYER1,0)
COMPUTER_PLAYER(PLAYER2,0)
COMPUTER_PLAYER(PLAYER_GOOD,0)

ALLY_PLAYERS(PLAYER0,PLAYER1)
ALLY_PLAYERS(PLAYER2,PLAYER_GOOD)

ADD_CREATURE_TO_POOL(FLY,10)
ADD_CREATURE_TO_POOL(BUG,9)
ADD_CREATURE_TO_POOL(SPIDER,8)
ADD_CREATURE_TO_POOL(DEMONSPAWN,9)
ADD_CREATURE_TO_POOL(SORCEROR,8)
ADD_CREATURE_TO_POOL(BILE_DEMON,5)
ADD_CREATURE_TO_POOL(DRAGON,7)
ADD_CREATURE_TO_POOL(HELL_HOUND,15)

ADD_CREATURE_TO_POOL(TROLL,25)
ADD_CREATURE_TO_POOL(ORC,20)
ADD_CREATURE_TO_POOL(DARK_MISTRESS,15)
ADD_CREATURE_TO_POOL(TENTACLE,15)
ADD_CREATURE_TO_POOL(HORNY,12)

REM ********** Available creatures ********** 

                CREATURE_AVAILABLE(PLAYER0,TROLL,1,1)
                CREATURE_AVAILABLE(PLAYER0,ORC,1,1)
                CREATURE_AVAILABLE(PLAYER0,TENTACLE,1,1)
                CREATURE_AVAILABLE(PLAYER0,DARK_MISTRESS,1,1)
                CREATURE_AVAILABLE(PLAYER0,HORNY,1,1)
                CREATURE_AVAILABLE(PLAYER1,TROLL,1,1)
                CREATURE_AVAILABLE(PLAYER1,ORC,1,1)
                CREATURE_AVAILABLE(PLAYER1,TENTACLE,1,1)
                CREATURE_AVAILABLE(PLAYER1,DARK_MISTRESS,1,1)
                CREATURE_AVAILABLE(PLAYER1,HORNY,1,1)
                CREATURE_AVAILABLE(PLAYER2,FLY,1,1)
                CREATURE_AVAILABLE(PLAYER2,BUG,1,1)
                CREATURE_AVAILABLE(PLAYER2,SPIDER,1,1)
                CREATURE_AVAILABLE(PLAYER2,SORCEROR,1,1)
                CREATURE_AVAILABLE(PLAYER2,DEMONSPAWN,1,1)
                CREATURE_AVAILABLE(PLAYER2,HELL_HOUND,1,1)
                CREATURE_AVAILABLE(PLAYER2,BILE_DEMON,1,1)

IF(PLAYER2,DRAGON<8)
	NEXT_COMMAND_REUSABLE
	CREATURE_AVAILABLE(PLAYER2,DRAGON,1,1)
ENDIF

IF(PLAYER2,DRAGON>=8)
	NEXT_COMMAND_REUSABLE
	CREATURE_AVAILABLE(PLAYER2,DRAGON,0,0)
ENDIF

REM ********** Available rooms **********

		ROOM_AVAILABLE(ALL_PLAYERS,TREASURE,1,1)
		ROOM_AVAILABLE(ALL_PLAYERS,LAIR,1,1)
		ROOM_AVAILABLE(ALL_PLAYERS,RESEARCH,1,1)
		ROOM_AVAILABLE(PLAYER0,TRAINING,1,1)
		ROOM_AVAILABLE(PLAYER0,GARDEN,1,1)
		ROOM_AVAILABLE(PLAYER0,GUARD_POST,1,0)
		ROOM_AVAILABLE(PLAYER0,WORKSHOP,1,0)
		ROOM_AVAILABLE(PLAYER0,BARRACKS,1,1)
		ROOM_AVAILABLE(PLAYER0,TORTURE,1,0)
		ROOM_AVAILABLE(PLAYER1,TRAINING,1,1)
		ROOM_AVAILABLE(PLAYER1,GARDEN,1,1)
		ROOM_AVAILABLE(PLAYER1,GUARD_POST,1,0)
		ROOM_AVAILABLE(PLAYER1,WORKSHOP,1,0)
		ROOM_AVAILABLE(PLAYER1,BARRACKS,1,0)
		ROOM_AVAILABLE(PLAYER1,TORTURE,1,0)
		ROOM_AVAILABLE(PLAYER2,TRAINING,1,0)
		ROOM_AVAILABLE(ALL_PLAYERS,TEMPLE,1,0)

REM ********** Available spells **********

                MAGIC_AVAILABLE(ALL_PLAYERS,POWER_HAND,1,1)
        	MAGIC_AVAILABLE(ALL_PLAYERS,POWER_SLAP,1,1)
		MAGIC_AVAILABLE(PLAYER1,POWER_IMP,1,1)
		MAGIC_AVAILABLE(PLAYER2,POWER_IMP,1,1)
		MAGIC_AVAILABLE(PLAYER0,POWER_SPEED,1,0)
		MAGIC_AVAILABLE(PLAYER0,POWER_CALL_TO_ARMS,1,0)
		MAGIC_AVAILABLE(PLAYER0,POWER_LIGHTNING,1,0)
		MAGIC_AVAILABLE(PLAYER0,POWER_CHICKEN,1,0)
		MAGIC_AVAILABLE(PLAYER1,POWER_SPEED,1,0)
		MAGIC_AVAILABLE(PLAYER1,POWER_CALL_TO_ARMS,1,0)
		MAGIC_AVAILABLE(PLAYER1,POWER_LIGHTNING,1,0)
		MAGIC_AVAILABLE(PLAYER1,POWER_CHICKEN,1,0)
		MAGIC_AVAILABLE(PLAYER2,POWER_PROTECT,1,0)
		MAGIC_AVAILABLE(PLAYER2,POWER_DISEASE,1,0)
		MAGIC_AVAILABLE(PLAYER2,POWER_CAVE_IN,1,0)
		MAGIC_AVAILABLE(PLAYER2,POWER_HOLD_AUDIENCE,1,0)

IF(PLAYER0,TOTAL_IMPS>=26)
	NEXT_COMMAND_REUSABLE
	MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,0,0)
ENDIF

IF(PLAYER0,TOTAL_IMPS<26)
	NEXT_COMMAND_REUSABLE
	MAGIC_AVAILABLE(ALL_PLAYERS,POWER_IMP,1,1)
ENDIF

REM ********** Available doors & traps **********

                DOOR_AVAILABLE(PLAYER0,WOOD,1,0)
		DOOR_AVAILABLE(PLAYER0,BRACED,1,0)
                DOOR_AVAILABLE(PLAYER0,STEEL,1,0)
		TRAP_AVAILABLE(PLAYER0,ALARM,1,0)
		TRAP_AVAILABLE(PLAYER0,LIGHTNING,1,0)
                TRAP_AVAILABLE(PLAYER0,BOULDER,1,0)
		TRAP_AVAILABLE(PLAYER0,WORD_OF_POWER,1,0)
                DOOR_AVAILABLE(PLAYER1,WOOD,1,0)
		DOOR_AVAILABLE(PLAYER1,BRACED,1,0)
                DOOR_AVAILABLE(PLAYER1,STEEL,1,0)
		TRAP_AVAILABLE(PLAYER1,ALARM,1,0)
		TRAP_AVAILABLE(PLAYER1,LIGHTNING,1,0)
                TRAP_AVAILABLE(PLAYER1,BOULDER,1,0)
		TRAP_AVAILABLE(PLAYER1,WORD_OF_POWER,1,0)

REM ********** Game settings **********

IF(PLAYER0,DUNGEON_DESTROYED == 1)
	LOSE_GAME
ENDIF

IF(PLAYER1,DUNGEON_DESTROYED == 1)
	LOSE_GAME
ENDIF

SET_CREATURE_HEALTH(KNIGHT,4000)
SET_CREATURE_ARMOUR(KNIGHT,200)
SET_CREATURE_STRENGTH(KNIGHT,200)

REM ********** Parties **********
    
CREATE_PARTY(ONE)
	ADD_TO_PARTY(ONE,KNIGHT,10,1000,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ONE,MONK,10,1000,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ONE,MONK,10,1000,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ONE,SAMURAI,10,1000,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(ONE,SAMURAI,10,1000,ATTACK_ENEMIES,0)

CREATE_PARTY(TWO)
	ADD_TO_PARTY(TWO,BARBARIAN,10,700,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(TWO,BARBARIAN,10,700,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(TWO,GIANT,10,700,ATTACK_ENEMIES,0)
	ADD_TO_PARTY(TWO,GIANT,10,700,ATTACK_ENEMIES,0)

REM ********** Triggers & End game **********

SET_TIMER(PLAYER_GOOD,TIMER0)
SET_FLAG(PLAYER_GOOD,FLAG0,0)
SET_FLAG(PLAYER_GOOD,FLAG1,0)
SET_FLAG(PLAYER_GOOD,FLAG2,0)

IF(PLAYER_GOOD,TIMER0>=5000)
	ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,8,DUNGEON_HEART,PLAYER0,1,0)
	ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,7,ACTION_POINT,15,1,0)
ENDIF

IF_ACTION_POINT(1,PLAYER0)
	IF(PLAYER_GOOD,FLAG0==0)
		SET_TIMER(PLAYER_GOOD,TIMER1)
		IF(PLAYER_GOOD,TIMER1>=25)
			NEXT_COMMAND_REUSABLE
			ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,3,1,2,20)
			NEXT_COMMAND_REUSABLE
			ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,2,1,3,30)
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_GOOD,TIMER1)
			NEXT_COMMAND_REUSABLE
			RESET_ACTION_POINT(1)
		ENDIF
	ENDIF
ENDIF

IF_ACTION_POINT(4,PLAYER0)
	SET_FLAG(PLAYER_GOOD,FLAG0,1)
	SET_TIMER(PLAYER_GOOD,TIMER3)
ENDIF

IF_ACTION_POINT(1,PLAYER1)
	IF(PLAYER_GOOD,FLAG0==0)
		SET_TIMER(PLAYER_GOOD,TIMER1)
		IF(PLAYER_GOOD,TIMER1>=25)
			NEXT_COMMAND_REUSABLE
			ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,ARCHER,3,1,2,20)
			NEXT_COMMAND_REUSABLE
			ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,THIEF,2,1,3,30)
			NEXT_COMMAND_REUSABLE
			SET_TIMER(PLAYER_GOOD,TIMER1)
			NEXT_COMMAND_REUSABLE
			RESET_ACTION_POINT(1)
		ENDIF
	ENDIF
ENDIF

IF_ACTION_POINT(4,PLAYER1)
	SET_FLAG(PLAYER_GOOD,FLAG0,1)
ENDIF

IF_ACTION_POINT(5,PLAYER0)
	IF(PLAYER_GOOD,FLAG2==0)
		SET_TIMER(PLAYER_GOOD,TIMER2)
		SET_FLAG(PLAYER_GOOD,FLAG2,1)
	ENDIF
ENDIF

IF_ACTION_POINT(5,PLAYER1)
	IF(PLAYER_GOOD,FLAG2==0)
		SET_TIMER(PLAYER_GOOD,TIMER2)
		SET_FLAG(PLAYER_GOOD,FLAG2,1)
	ENDIF
ENDIF

IF(PLAYER_GOOD,TIMER2>=4000)
	IF(PLAYER_GOOD,DUNGEON_DESTROYED==0)
		NEXT_COMMAND_REUSABLE
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DRAGON,6,2,1,0)
		NEXT_COMMAND_REUSABLE
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DEMONSPAWN,6,1,3,0)
		NEXT_COMMAND_REUSABLE
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DRAGON,9,2,1,0)
		NEXT_COMMAND_REUSABLE
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,DEMONSPAWN,9,1,3,0)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER_GOOD,TIMER2)
	ENDIF
ENDIF

IF(PLAYER_GOOD,TIMER3>=4000)
	IF(PLAYER_GOOD,DUNGEON_DESTROYED==0)
		NEXT_COMMAND_REUSABLE
		ADD_CREATURE_TO_LEVEL(PLAYER_GOOD,BARBARIAN,3,3,6,0)
		NEXT_COMMAND_REUSABLE
		SET_TIMER(PLAYER_GOOD,TIMER3)
	ENDIF
ENDIF

IF(PLAYER_GOOD,DUNGEON_DESTROYED==1)
	SET_TIMER(PLAYER_GOOD,TIMER4)
	IF(PLAYER_GOOD,TIMER4>=1000)
		ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,10,DUNGEON_HEART,PLAYER0,10,0)
		ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,12,DUNGEON_HEART,PLAYER0,10,0)
		ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,13,DUNGEON_HEART,PLAYER0,10,0)
		ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,14,DUNGEON_HEART,PLAYER0,10,0)
		ADD_TUNNELLER_TO_LEVEL(PLAYER_GOOD,11,ACTION_POINT,13,10,0)
		IF(PLAYER_GOOD,TIMER4>=4000)
			ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,ONE,16,ACTION_POINT,17,10,1000)
			ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TWO,16,ACTION_POINT,17,10,1000)
			ADD_TUNNELLER_PARTY_TO_LEVEL(PLAYER_GOOD,TWO,16,ACTION_POINT,17,10,1000)
			SET_FLAG(PLAYER_GOOD,FLAG1,1)
		ENDIF
	ENDIF
ENDIF

IF(PLAYER_GOOD,FLAG1==1)
	IF(PLAYER_GOOD,TOTAL_CREATURES==0)
		IF(PLAYER2,DUNGEON_DESTROYED==1)
			WIN_GAME
		ENDIF
	ENDIF
ENDIF