Documentation for Changing  V2.3 style Triggers to  PL/SQL

Command Syntax In  V2.3

#EXEMACRO      used to exexcute a series of actions on a form.

#EXEMACRO macro_statement ; …….. ;

where macro_statement ={ function_code | CASE_statement }

where function_code may be one of the following statements

CALLQRY

NULL

NOOP

CALL

CALLINPUT

CALLQRY

EXETRG

GOBLK

GOFLD

Where  CASE_statement =  CASE { variable |  ‘constant ‘ } IS

WHEN { variable |  ‘constant ‘ }

THEN  macro_statement ; ………;

-

.

.

[ WHEN OTHERS

THEN    macro_statement;…….; ]

END CASE;

Where variable = { [ block.] field | GLOBAL.var_name |

SYSTEM.var_name | var_ ref }

Where var_ref = &variable

#COPY  used to copy constants,field values or global or system variables from a source to a destination

#COPY  source  destination

Where source  =  { [ block.] field | GLOBAL.var_name |

SYSTEM.var_name | ‘constant’ var_ ref }

Where destination = { [ block.] field | GLOBAL.var_name  | var_ ref }

#HOST used to carry out operating  system  commands.

#HOST { ‘command_string’ | [block .] field | var_ref  }

HOW MACROS ARE PROCESSED IN V2.3

When SQL* Forms executes a trigger step that contains a macro , it performs all the functions in                  order. EXAMPLE

#EXEMACRO NXTBLK ; NXTSET ; PRVBLK ;

performs as if the operator had pressed [NEXTBLOCK] , [NEXT SET  OF RECORDS ]  and

[PREVIOUS BLOCK ] , in that order.

The NOOP  and  NULL functions simply do nothing

An   #EXECUTEMACRO command succeds if all of its function codes can be executed.

It fails if  one cannot be executed for any reason, including a syntax error.

TRIGGER STEP ATTRIBUTES IN V2.3

1. Abort trigger when step fails:  If this option is selected and a failure label is not selected -  failure of the step will halt execution of the trigger. Whether the trigger itself succeeds or fails depends on the ‘Return Success When Aborting Trigger’ option. This option is selected by default since failure of a trigger step normally means that something has gone wrong and you want to stop processing.

2. Reverse return code:  If this option is selected the normal criteria for success and failure are reversed. It is most often used to :

· make sure a corresponding record does not exist  (i.e.  the select  statement fails) before carrying out an action

· display a  failure message when the operator presses a key you have disabled,even though the trigger itself succeeds.

3.Return success when aborting trigger: This option is meaningful only if

“Abort trigger when step fails” is selected.if  both the options are selected,the trigger itself will

succeed  even though  the step fails and execution is halted.

4.Separate cursor data area:Normally,each trigger step is assigned its own cursor

(memory space) for processing.if memory is scarce,  however , you can  conserve it.

Examples given below show V2.3  changed to PL/SQL

1) DEFINE TRIGGER

NAME = KEY-F7

TRIGGER_TYPE = V2

DEFINE STEP

TEXT = <<< #exemacro null;  >>>

ENDDEFINE STEP

ENDDEFINE TRIGGER

DEFINE TRIGGER

NAME = KEY-F7

TRIGGER_TYPE = V3

SHOW_KEY = OFF

TEXT = <<<   null;   >>>

ENDDEFINE TRIGGER

2) DEFINE TRIGGER

NAME = KEY-STARTUP

TRIGGER_TYPE = V2

DEFINE STEP

TEXT = <<<   #EXEMACRO NOFAIL exetrg GET_START;  >>>

ENDDEFINE STEP

DEFINE STEP

TEXT = <<<   #vms$logical sys$print :man_det.queue  >>>

ENDDEFINE STEP

ENDDEFINE TRIGGER

DEFINE TRIGGER

NAME = KEY-STARTUP

TRIGGER_TYPE = V3

TEXT = <<<

GET_START;

user_exit('vms$logical sys$print :man_det.queue');

kcheck_failure;    >>>

ENDDEFINE TRIGGER

3) DEFINE TRIGGER

  NAME = ERROR

TRIGGER_TYPE = V2

DEFINE STEP

COMMENT = <<< General trigger for signaling error in a trigger step.

It can be used for displaying error messages, or aborting case statements. >>>

TEXT = <<<  #EXEMACRO NOFAIL null;   >>>

REVERSE = ON

ENDDEFINE STEP

DEFINE TRIGGER

COMMENT = <<<           >>>

NAME = ERROR

TRIGGER_TYPE = V3

TEXT = <<<       -- General trigger for signaling error in a trigger step.

-- It can be used for displaying error messages, or aborting case

-- statements.

raise form_trigger_failure;   >>>

ENDDEFINE TRIGGER

4) DEFINE TRIGGER

 NAME = GET_START

TRIGGER_TYPE = V2

DEFINE STEP

COMMENT = <<<  Get the username. If an OPS$-username is used,

then the 'OPS$' is omitted.  >>>

TEXT = <<<

Select  decode(instr(USER,'OPS$'),1,substr(USER,5,4),substr(USER,1,4))

into  HEADER.USERID

from  DUAL    >>>

ENDDEFINE STEP

ENDDEFINE TRIGGER

DEFINE PROCEDURE

COMMENT = <<<            >>>

NAME = GET_START

DEFINITION = <<<

procedure get_start is

begin

-- Get the username. If an OPS$-username is used, then the 'OPS$' is

-- omitted.

if instr(USER, 'OPS$') = 1 then

:global.decode1 := substr(USER, 5, 4);

else

:global.decode1 := substr(USER, 1, 4);

end if;

:HEADER.USERID := :global.decode1;

end;      >>>

ENDDEFINE PROCEDURE

5) DEFINE TRIGGER

NAME = KEY-CLRFRM

TRIGGER_TYPE = V2

DESCRIPTION = Print manifest

DEFINE STEP

TEXT = <<<  #EXEMACRO NOFAIL exetrg COPY_MAN_DET;   >>>

ENDDEFINE STEP

DEFINE STEP

TEXT = <<<  #Copy  'MA'  MANIFEST.STATUS_CODE   >>>

ENDDEFINE STEP

DEFINE STEP

TEXT = <<<

#EXEMACRO case '' is

when MANIFEST.CON_KEY_TO,

MAN_DET.BOAT,

MANIFEST.DEPARTURE_DATE,

MANIFEST.MANIFEST_ID then exetrg error;

end case;      >>>

FAIL_MESSAGE = Consignee, boat, deparure and manifest must be filled!

ENDDEFINE STEP

DEFINE STEP

TEXT = <<<  #EXEMACRO NOFAIL commit;    >>>

ENDDEFINE STEP

DEFINE STEP

TEXT = <<<

Select  'Submit'   ||

'/nolog'   ||

'/noprint' ||

'/characteristic=MMP$CHAR' ||

'/priority=' || substr(:HEADER.TODAY,1,2) ||

'/queue=MANI$BATCH' ||

'/parameter=("' || :MANIFEST.MANIFEST_NO || '","' ||

:MAN_DET.ORD ||

'","MA","N","'||:MAN_DET.RSU||'","0","'||

:MAN_DET.QUEUE ||

'","OFF") TRP$REPORTS:MANIFEST'

into  HEADER.VMS$COMMAND

from  SYS.DUAL     >>>

FAIL_MESSAGE = Manifest can not be printed.

ENDDEFINE STEP

DEFINE STEP

TEXT = <<<   #VMS$COMMAND    >>>

FAIL_MESSAGE = Manifest can not be printed.

ENDDEFINE STEP

DEFINE STEP

TEXT = <<<   #Copy  ''  HEADER.VMS$COMMAND   >>>

FAIL_MESSAGE = Print job has been started.

REVERSE = ON

IGNORE = ON

ENDDEFINE STEP

ENDDEFINE  TRIGGER

DEFINE TRIGGER

NAME = KEY-CLRFRM

TRIGGER_TYPE = V3

DESCRIPTION = Print manifest

TEXT = <<<

COPY_MAN_DET;

:MANIFEST.STATUS_CODE := 'MA';

if :MANIFEST.CON_KEY_TO is null or :MAN_DET.BOAT is null or

:MANIFEST.DEPARTURE_DATE is null or :MANIFEST.MANIFEST_ID

is null then

execute_trigger('error');

if form_failure then

bmessage('Consignee, boat, deparure and manifest mus' ||

't be filled!');

raise form_trigger_failure;

end if;

end if;

commit_form;

:HEADER.VMS$COMMAND := 'Submit' || '/nolog' || '/noprint' ||

'/characteristic=MMP$CHAR' || '/priority=' || substr(

:HEADER.TODAY, 1, 2) || '/queue=MANI$BATCH' ||

'/parameter=("' || to_char(:MANIFEST.MANIFEST_NO) || '","' ||

to_char(:MAN_DET.ORD) || '","MA","N","' || :MAN_DET.RSU ||

'","0","' || :MAN_DET.QUEUE || '","OFF") TRP$REPORTS:MANIF' ||

'EST';

user_exit('VMS$COMMAND');

if form_failure then

bmessage('Manifest can not be printed.');

raise form_trigger_failure;

end if;

:HEADER.VMS$COMMAND := '';

bmessage('Print job has been started.');    >>>

ENDDEFINE TRIGGER

6) DEFINE TRIGGER
NAME = PRE-INSERT

TRIGGER_TYPE = V2

DEFINE STEP

TEXT = <<<  #EXEMACRO NOFAIL null;  >>>

FAIL_MESSAGE = Insert not allowed !

REVERSE = ON

ENDDEFINE STEP

ENDDEFINE TRIGGER

DEFINE TRIGGER

NAME = PRE-INSERT

TRIGGER_TYPE = V3

TEXT = <<<  bmessage('Insert not allowed !');

raise form_trigger_failure;   >>>

ENDDEFINE TRIGGER
7) DEFINE TRIGGER

NAME = POST-QUERY

TRIGGER_TYPE = V2

DEFINE STEP

TEXT = <<<    Select  DESCRIPTION

into  MANIFEST.DESCRIPTION

from  OPS$DBA.CONSIGNEE

where CON_KEY = :MANIFEST.CON_KEY_TO    >>>

ABORT = OFF

ENDDEFINE STEP

DEFINE STEP

TEXT = <<<   Select  decode(:MANIFEST.TRANSPORT,

'B','oat','H','elic.','O','ther','T','hurs.',''),

decode(:MANIFEST.URGENT,'Y','es','N','o','')

into  MANIFEST.TRANSPORT_X,

MANIFEST.URGENT_X

from  SYS.DUAL    >>>

ENDDEFINE STEP

ENDDEFINE TRIGGER

DEFINE TRIGGER

NAME = POST-QUERY

TRIGGER_TYPE = V3

TEXT = <<<    declare     cursor temp_cursor is

Select  DESCRIPTION from CONSIGNEE

where CON_KEY = :MANIFEST.CON_KEY_TO;

begin

open temp_cursor;

fetch temp_cursor into :MANIFEST.DESCRIPTION;

end;

if :MANIFEST.TRANSPORT = 'B' then

:global.decode1 := 'oat';

elsif :MANIFEST.TRANSPORT = 'H' then

:global.decode1 := 'elic.';

elsif :MANIFEST.TRANSPORT = 'O' then

:global.decode1 := 'ther';

elsif :MANIFEST.TRANSPORT = 'T' then

:global.decode1 := 'hurs.';

else

:global.decode1 := '';

end if;

:MANIFEST.TRANSPORT_X := :global.decode1;

if :MANIFEST.URGENT = 'Y' then

:global.decode1 := 'es';

elsif :MANIFEST.URGENT = 'N' then

:global.decode1 := 'o';

else

:global.decode1 := '';

end if;

:MANIFEST.URGENT_X := :global.decode1;   >>>

ENDDEFINE TRIGGER

8) DEFINE TRIGGER

NAME = POST-CHANGE

TRIGGER_TYPE = V2

DEFINE STEP

TEXT = <<<     Select  ''    from  OPS$DBA.CONSIGNEE

where CON_KEY = :HEADER.CON_KEY_FROM

and   ACTIVE  = 'A'    >>>

FAIL_MESSAGE = Consignee does not exist !

ENDDEFINE STEP

ENDDEFINE TRIGGER

DEFINE TRIGGER

NAME = POST-CHANGE

TRIGGER_TYPE = V3

TEXT = <<<    declare    temp_buffer char(255);

cursor temp_cursor is

Select  '' from CONSIGNEE

where CON_KEY = :HEADER.CON_KEY_FROM

and   ACTIVE  = 'A';

begin

open temp_cursor;

fetch temp_cursor into temp_buffer;

if temp_cursor%notfound then

bmessage('Consignee does not exist !');

raise form_trigger_failure;

end if;

end;    >>>

ENDDEFINE TRIGGER

9) DEFINE TRIGGER

NAME = KEY-NXTBLK

TRIGGER_TYPE = V2

DEFINE STEP

TEXT = <<<    #EXEMACRO NOFAIL case MANIFEST.STATUS_CODE is

when 'TO'   then exetrg ERROR;

when others then null;

end  case;    >>>

FAIL_MESSAGE = This is only an intermediary manifest for pending items.

ENDDEFINE STEP

DEFINE STEP

TEXT = <<<   #EXEMACRO NOFAIL exetrg COPY_MAN;  >>>

ENDDEFINE STEP

DEFINE STEP

TEXT = <<<   #EXEMACRO NOFAIL goblk MAN_DET;    >>>

ENDDEFINE STEP

ENDDEFINE TRIGGER

DEFINE TRIGGER

NAME = KEY-NXTBLK

TRIGGER_TYPE = V3

TEXT = <<<

if :MANIFEST.STATUS_CODE = 'TO' then

execute_trigger('ERROR');

if form_failure then

bmessage('This is only an intermediary manifest for ' ||

'pending items.');

raise form_trigger_failure;

end if;

end if;

COPY_MAN;

go_block('MAN_DET');    >>>

ENDDEFINE TRIGGER

9) DEFINE TRIGGER

NAME = INS_STATUS_MA

TRIGGER_TYPE = V2

DEFINE STEP

TEXT = <<<  #exemacro null;    >>>

FAIL_MESSAGE = Table MAT_REQ_STATUS can not be locked.

ENDDEFINE STEP

DEFINE STEP

TEXT = <<<    Insert

into  OPS$DBA.MAT_REQ_STATUS

(     MR_NO,

EVENT,

EVENT_DATE,

USERID  )

values

(     :MAT_REQ.MR_NO,

'AM',

SYSDATE,

:HEADER.USERID  )   >>>

FAIL_MESSAGE = Status record can not be inserted into table MAT_REQ_STATUS.

ENDDEFINE STEP

ENDDEFINE TRIGGER

DEFINE PROCEDURE

NAME = INS_STATUS_MA

DEFINITION = <<<   procedure ins_status_ma is

begin

Insert

into  OPS$DBA.MAT_REQ_STATUS

(     MR_NO,EVENT,EVENT_DATE,USERID  )

values

(     :MAT_REQ.MR_NO,'AM',SYSDATE,:HEADER.USERID  );

if sql%notfound then

bmessage('Status record can not be inserted into table ' ||

'MAT_REQ_STATUS.');

raise form_trigger_failure;

end if;

end;   >>>

ENDDEFINE PROCEDURE


Given above are some examples of how FC (Forms Converter ) converts V2 style triggers to  corresponding PL/SQL. 

