;Dexer trainer v1.1 by Mozart
initevents

;***edit to match your settings***
;your uo screen size!
set %screenresx 800
set %screenresy 600

;how long it takes to heal
set %healwait 7
;how long wait before give npc gold again
set %goldwait 400
;how much give gold each time
set %howmuch 14
;************************

set %centerx %screenresx / 2
set %centery %screenresy / 2

gosub buildmenu
gosub init

set %goldtimer #scnt + %goldwait
waitloop:
if #menubutton <> N/A 1
	gosub #menubutton
goto waitloop


sub main
	set #menubutton N/A
	menu delete main
	menu button stop 0 40 70 20 Stop
	event macro 6 0
	msg all guard me$
	wait 20
	msg all guard me$
	wait 20
	msg all guard me$
	wait 20
	msg all follow me$

	set #ltargetid %npc
	wait 20
	event macro 27 0
	mainloop:

	if %armflag = 1
	{
		set %arm 0
		for %line 5 1
		{
		   	scanjournal %line
			if %arm = 0
			{
		   		if destroyed in #journal
				{
					deletejournal
	     			 	gosub armwep
					set %arm 1
				 	wait 30
				}
			}
		}
	}

	if %goldflag = 1
	{	
		if %goldtimer < #scnt 3
			gosub walk #enemyid
			gosub dropGold %howmuch
			set %goldtimer #scnt + %goldwait
	}
	if %healflag = 1
	{
		if #enemyhits < 80
			gosub heal
	}
	if %timer < #scnt 2
		set %timer #scnt + 200
		gosub staylogged

	if #menubutton <> N/A 1
		gosub #menubutton

	goto mainloop
return



; SUBS
;______________

sub staylogged
	event macro 13 16
	target
	event macro 23 0
return

sub stop
	menu delete status
	menu text status 0 0 Script haltted
	menu delete stop
	menu delete hbutton
	halt
return

sub hbutton
	set #menubutton N/A
	if %hflag = 0
	{
		gosub menuclear
		set %hflag 1
		menu window size 250 340	
		menu button hbutton 80 40 70 20 Help
		menu font style bu
		menu text help 5 80  What you need to run this script:
		menu font style
		menu text help2 5 95  - some bandages $- gold $- weapons in backbag$- hired npc warrior
		menu font style bu
		menu text help3 5 160 What type npc use in different skill levels:
		menu font style
		menu text help4 5 175 30-60: 6gp wrestlers$60-75: 8gp wrestlers$75-90: 7gp fighters:$90+: 8gp fighters$8gp fighters(paladins) are easy to find$from trinsic or delucia$$CAUNTION: do not use easyuos $"Don't move cursor" option.$Also make sure there is one$tile free north east from npc.
		wait 10
		return
	}

	if %hflag = 1
	{
		gosub menuclear
		menu button hbutton 80 40 70 20 Setup
		if %armflag = 1 2
			menu button abutton 10 100 10 10 X
			menu text help 25 98 Auto arming is on
		if %armflag = 0 2
			menu button abutton 10 100 10 10 _
			menu text help 25 98  Auto arming is off

		if %goldflag = 1 2
			menu button gbutton 10 120 10 10 X
			menu text help 25 118 Auto give gold is on

		if %goldflag = 0 2
			menu button gbutton 10 120 10 10 _
			menu text help 25 118 Auto give gold is off

		if %healflag = 1 2
			menu button hebutton 10 140 10 10 X
			menu text help 25 138 Auto heal enemy is on

		if %healflag = 0 2
			menu button hebutton 10 140 10 10 _
			menu text help 25 138 Auto heal enemy is off

		set %hflag 2
		return
	}

	

	if %hflag = 2
	{
		gosub menuclear
		set %hflag 0	
		menu window size 250 60
		menu button hbutton 80 40 70 20 Hidden
		wait 10
		return
	}
return

sub gbutton
	set %hflag 1
	if %goldflag = 1 3
		set %goldflag 0
		gosub hbutton
		return
	if %goldflag = 0 3
		set %goldflag 1
		gosub hbutton
		return
return

sub abutton
	set %hflag 1
	if %armflag = 1 3
		set %armflag 0
		gosub hbutton
		return
	if %armflag = 0 3
		set %armflag 1
		gosub hbutton
		return
return

sub hebutton
	set %hflag 1
	if %healflag = 1 3
		set %healflag 0
		gosub hbutton
		return
	if %healflag = 0 3
		set %healflag 1
		gosub hbutton
		return
return

sub menuclear

	menu delete help
	menu delete help2
	menu delete help3
	menu delete help4
	menu delete abutton
	menu delete gbutton
return


sub buildmenu
	set %hflag 0
	set %goldflag 1
	set %armflag 1
	set %healflag 1
	menu clear
	menu hideeuo
	menu window size 250 60
	menu window color $AAAAAA
	menu window title Dexer trainer by Mozart v1.1
	menu font size 8
	menu font align left
	menu font color $000000
	menu font bgcolor $AAAAAA
	menu text status 0 0 Please wait.....
	menu show
	;menu hideeuo
return


sub init
	;TSF = npc dagger
	set %timer #scnt + 200
	set %hcounter #scnt + %healwait

	menu delete status
	menu text status 0 0 Please wait.....$opening paperdoll
	;;open paperdoll
	event macro 8 1 
	wait 50 
	contpos 700 0

	menu delete status
	menu text status 0 0 Please wait.....$opening backbag
	;;open backbag
	wait 40
	event macro 8 7
	wait 50
	contpos 700 350
	wait 30

	menu delete status
	menu text status 0 0 Please wait.....$searching bandages
	wait 20
	findbandages:
	finditem ZLF
	if #findkind = -1
		halt
	if #findkind <> 0 2
		ignoreitem #findid
		goto findbandages
	set #lobjectid #findid

	menu delete status
	menu text status 0 0 Please target one of weapons in your backbag$ that your going to use
	set #targcurs 1
	target
	wait 10
	waittargc:
	if #targcurs = 1 2
		wait 20
		goto waittargc
	wait 10
	finditem #ltargetid
	wait 10
	set %weapontype #findtype
	menu delete status

	menu delete status
	menu text status 0 0 Please target your npc warrior
	set #targcurs 1
	target
	wait 10
	waittargc2:
	if #targcurs = 1 2
		wait 20
		goto waittargc2
	wait 10
	set %npc #ltargetid
	menu delete status


	menu text status 0 0 Ready
	menu button main 0 40 70 20 Start
	menu button hbutton 80 40 70 20 Hidden
	
return

sub heal

if %hcounter < #scnt
{
	set #ltargetid #enemyid
	wait 10
	event macro 17 0
	target
	event macro 22 0
	set %hcounter #scnt + %healwait
}
return


sub armwep
	ignoreitem reset
	findweapon:
	finditem %weapontype
	if #findkind = -1
		halt
	if #findkind <> 0 2
		ignoreitem #findid
		goto findweapon
	wait 20
	event drag #findid
	click 800 50 p
	click 800 50 p
	wait 2s
	click 850 220 p
	;set #rhandid #findid
	;event macro 24 2
return


sub dropGold
{
	ignoreitem reset
	findgold:
	finditem POF
	
	if #findkind = -1
		halt
	if #findkind <> 0 2
		ignoreitem #findid
		goto findgold

	event drag #findid
	wait 10
	msg %1 $
	finditem #charid
	gosub ClickScreenPos #findx #findy 0 -40
	msg all follow me$
	return
}

sub walk
{
	finditem %1
	wait 10
	set %movex #findx + 1
	set %movey #findy - 1
	move %movex %movey 0 5s
	return
}

; =====================================================================
; Name: ClickScreenPos
; Purpose: Clicks on the screen given by world coordinates (with displacement)
; %1 = world x-coordinate
; %2 = world y-coordinate
; %3 = screen x displacement (this will be added to the screen coordinate)
; %4 = screen y displacement (this will be added to the screen coordinate)
sub ClickScreenPos
	set %_destx %1
	set %_desty %2
	set %_dispx %3
	set %_dispy %4

	finditem #charid
	set %_deltax %_destx - #findx
	set %_deltay #findy - %_desty

	set %_deltax %_deltax * 22
	set %_deltay %_deltay * 22

	set %_movex %_deltay
	set %_movex %_movex + %_deltax

	set %_movey %_deltax
	set %_movey %_movey - %_deltay

	set %_cursorx %centerx + %_movex
	set %_cursory %centery + %_movey

	set %_cursorx %_cursorx + %_dispx
	set %_cursory %_cursory + %_dispy

	set %outsidescreen 1

	if %_cursorx > 0
	{
		if %_cursory > 0
		{
			if %_cursorx < %screenresx
			{
				if %_cursory < %screenresy
				{
					set %outsidescreen 0
					click %_cursorx %_cursory p
				}
			}
		}
	}
return