      /TITLE UPDRPG4: UPDRPGSRC: Resequence new member
      *--------------------------------------------------------------*
      *  Programmers Group & Management Resource    Copyright  1997  *
      *                                                              *
      *                           \\\\\\\                            *
      *                          ( o   o )                           *
      *----------------------oOO----(_)----OOo-----------------------*
      *                                                              *
      *  System name. . :  PGMR Tool                                 *
      *  Program name . :  UPDRPG4                                   *
      *  Text . . . . . :  Resequence new member                     *
      *                                                              *
      *  Author . . . . :  Alexander Nubla                           *
      *  Creation date. :  11/26/97                                  *
      *                                                              *
      *                   ooooO              Ooooo                   *
      *                   (    )             (    )                  *
      *--------------------(   )-------------(   )-------------------*
      *                     (_)               (_)                    *
      *                                                              *
      * MODIFICATION LOG :                                           *
      *            Task   Programmer/                                *
      *   Date      No.   Description                                *
      * --------  ------  ------------------------------------------ *
      * 11/18/97          Alex Nubla                                 *
      *                   Creation Date                              *
      *                   This program reads the source file and     *
      *                   updates the SRCSEQ field based on the      *
      *                   previous sequence to produce a proper      *
      *                   ascending sequence number                  *
      *                                                              *
      ****************************************************************
      /EJECT
      ****************************************************************
      *  F I L E   D E S C R I P T I O N   S P E C I F I C A T I O N *
      ****************************************************************
     FQRPGLESRC UF   F  112        DISK
      *
      *  Expanded source file
      *
      *--------------------------------------------------------------*
      *
      ****************************************************************
      *       D E F I N I T I O N     S P E C I F I C A T I O N      *
      ****************************************************************
      *
      *  Previous sequence number
      *
     D                 DS
     D #Prev                          6S 2 Inz
     D  OldSeq                        4S 0 Overlay(#Prev: 1)
     D  OldDec                        2S 0 Overlay(#Prev: 5)
      *--------------------------------------------------------------*
      *
      *  Current sequence number
      *
     D                 DS
     D #Curr                          6S 2 Inz
     D  CurSeq                        4S 0 Overlay(#Curr: 1)
     D  CurDec                        2S 0 Overlay(#Curr: 5)
      *--------------------------------------------------------------*
      *
      *  Standalone fields
      *
     D SrcAdd          S              3S 2
      *--------------------------------------------------------------*
      *
      /EJECT
      ****************************************************************
      *           I N P U T     S P E C I F I C A T I O N            *
      ****************************************************************
     IQRPGLESRC NS
     I                             S    1    6 2SRCSEQ
     I                             S    7   12 0SRCDAT
     I                                 13  112  SRCDTA
      /EJECT
      ****************************************************************
      *     C A L C U L A T I O N     S P E C I F I C A T I O N      *
      ****************************************************************
      *
      *  Entry parameter list
      *
     C     *Entry        Plist
     C                   Parm                    InSeq             3 2          Increment Seq
     C                   Eval      SrcAdd      = InSeq

      *----------------------------------------------------*
      *  Read in sequential order and update the Sequence  *
      *----------------------------------------------------*
     C                   Dow       *InLR       = *Off
     C                   Read      QRPGLESRC                              LR
     C                   If        Not *InLr
      *         *------------------------------------------*
      *         *  Compare previous with current seq no.   *
      *         *------------------------------------------*
     C                   If        SRCSEQ     <= #Prev
     C                   Eval      #Curr       = SRCSEQ
     C                   If        CurDec      = *Zeros
     C                   Eval      SRCSEQ      = OldSeq + 1
     C                   Else
     C                   Eval      SRCSEQ      = #Prev  + SrcAdd
     C                   EndIf
     C                   EndIf
     C                   Eval      #Prev       = SRCSEQ
     C                   Except    UPDSRC
     C                   EndIf
     C                   EndDo
      *
     C                   Return
      ****************************************************************
      *         O U T P U T     S P E C I F I C A T I O N          *
      ****************************************************************
     OQRPGLESRC E            UPDSRC
     O                       SRCSEQ
