     A****************************************************************
     A*                                                              *
     A*  Printer File . . . :   TS0010RD                             *
     A*  Text . . . . . . . :   WRKRMTWTR: Work with Remote Writers  *
     A*                                                              *
     A*  Author . . . . . . :   Alex Nubla                           *
     A*  Description  . . . :   This display file shows the overall  *
     A*                         status of each remote output queues  *
     A*                         in the system.                       *
     A*                                                              *
     A****************************************************************
     A*%%EC
     A                                      DSPSIZ(24 80 *DS3)
     A                                      PRINT
     A                                      HELP(01 'Help')
     A                                      CF01(01)
     A                                      CF03(03 'Exit')
     A****************************************************************
     A*                                                              *
     A*  Subfile Selection for all Remote Output Queue               *
     A*                                                              *
     A****************************************************************
     A          R TS0010S1                  SFL
     A  36                                  SFLNXTCHG
     A            @DESC         50A  H      TEXT('Source OUTQ Description')
     A            @TGTM         10A  H      TEXT('Target Machine')
     A            @TOQN         10A  H      TEXT('Target OUTQ Name')
     A            @TOQL         10A  H      TEXT('Target OUTQ Library')
     A            @OPT           2Y 0B 11  3TEXT('Option')
     A                                      VALUES(0 1 2 3 4 5 6 13 17)
     A                                      EDTCDE(Z)
     A                                      CHECK(FE)
     A N41                                  DSPATR(UL)
     A  41                                  DSPATR(ND)
     A  41                                  DSPATR(PR)
     A            @SOQN         10A  O 11  6TEXT('Source OUTQ Name')
     A            @SOQL         10A  O 11 17TEXT('Source OUTQ Library')
     A            @STS           5A  O 11 28TEXT('Remote Writer Status')
     A            @INFO         42A  O 11 34TEXT('Other Info')
     A****************************************************************
     A*                                                              *
     A*  Subfile Control (with Search Field for Source OUTQ Name)    *
     A*                                                              *
     A****************************************************************
     A          R TS0010C1                  SFLCTL(TS0010S1)
     A*%%TS  SD  19970206  160748  SISPG189    REL-V3R2M0  5763-PW1
     A                                      SFLPAG(0011)
     A  34                                  CF05(05 'Refresh')
     A                                      CF09(09 'Add new OUTQ')
     A  34                                  CF11(11 'Alternate View')
     A N99                                  ROLLUP(25)
     A N98                                  ROLLDOWN(26)
     A                                      BLINK
     A                                      KEEP
     A                                      OVERLAY
     A                                      PUTOVR
     A                                      SFLDSP
     A N33                                  SFLDSPCTL
     A  33                                  SFLCLR
     A  35                                  SFLEND(*MORE)
     A                                      SFLSIZ(&SFLSIZ)
     A            SFLSIZ         5S 0P
     A            RRNPAG1        4S 0H      SFLRCDNBR(CURSOR)
     A                                  1  2USER
     A                                      COLOR(BLU)
     A                                  1 29'INFORMATION TECHNOLOGY GROUP'
     A                                      DSPATR(HI)
     A                                  1 72DATE
     A                                      EDTCDE(Y)
     A                                      COLOR(BLU)
     A                                  2  2'System:'
     A                                      COLOR(BLU)
     A                                  2 10SYSNAME
     A                                      COLOR(BLU)
     A                                  2 31'Work with Remote Writers'
     A                                      COLOR(BLU)
     A                                  2 72TIME
     A                                      COLOR(BLU)
     A                                  4  2'Type options, press Enter.'
     A                                      COLOR(BLU)
     A                                  5  4'1=Start      2=Edit      3=Hold   -
     A                                         4=End      5=Work with Output Qu-
     A                                      eue'
     A                                      COLOR(BLU)
     A                                  6  4'6=Release   13=Delete   17=Disconn-
     A                                      ect'
     A                                      COLOR(BLU)
     A                                  8  6'Src Outq'
     A                                      DSPATR(HI)
     A                                  8 17'Src Outq'
     A                                      DSPATR(HI)
     A                                  8 28'Wtr'
     A                                      DSPATR(HI)
     A            DFTTL1        42A  O  8 34OVRDTA
     A                                      OVRATR
     A                                      DSPATR(HI)
     A                                  9  2'Opt'
     A                                      DSPATR(HI)
     A                                  9  6'Name'
     A                                      DSPATR(HI)
     A                                  9 17'Library'
     A                                      DSPATR(HI)
     A                                  9 28'Sts'
     A                                      DSPATR(HI)
     A            DFTTL2        42A  O  9 34OVRDTA
     A                                      OVRATR
     A                                      DSPATR(HI)
     A            DFPOS1        10A  B 10  6OVRDTA
     A                                      OVRATR
     A****************************************************************
     A*                                                              *
     A*  Command Option                                              *
     A*                                                              *
     A****************************************************************
     A          R TS0010D1                  OVERLAY
     A N34                             23  2'F3=Exit   F9=Add'
     A                                      COLOR(BLU)
     A  34N31                          23  2'F3=Exit   F5=Refresh   F9=Add   F1-
     A                                      1=Description'
     A                                      COLOR(BLU)
     A  34 31                          23  2'F3=Exit   F5=Refresh   F9=Add   F1-
     A                                      1=Target'
     A                                      COLOR(BLU)
      *           BUTTON         2Y 0B 23  2
      *                                     PSHBTNCHC(1 'F3=Exit'         CF03)
      * 34                                  PSHBTNCHC(2 'F5=Refresh'      CF05)
      *                                     PSHBTNCHC(3 'F9=Add'          CF09)
      * 34N31                               PSHBTNCHC(4 'F11=Description' CF11)
      * 34 31                               PSHBTNCHC(5 'F11=Target'      CF11)
      *                                     PSHBTNFLD( *NORSTCSR     +
      *                                               (*NUMCOL    4) +
      *                                               (*GUTTER    3))
     A****************************************************************
     A*                                                              *
     A*  Subfile message                                             *
     A*                                                              *
     A****************************************************************
     A          R MSGRCD                    SFL
     A                                      SFLMSGRCD(24)
     A            MSGID                     SFLMSGKEY
     A            PGMQ##                    SFLPGMQ
     A****************************************************************
     A*                                                              *
     A*  Subfile message control                                     *
     A*                                                              *
     A****************************************************************
     A          R MSGCTL                    SFLCTL(MSGRCD)
     A                                      OVERLAY
     A N43                                  SFLDSP
     A N43                                  SFLDSPCTL
     A N43                                  SFLINZ
     A  43                                  SFLCLR
     A  45
     AON45                                  SFLEND
     A                                      SFLSIZ(   2)
     A                                      SFLPAG(   1)
     A            PGMQ##                    SFLPGMQ
     A****************************************************************
     A*                                                              *
     A*  Window Record Update                                        *
     A*                                                              *
     A****************************************************************
     A          R TS0010D2
     A*%%TS  SD  19970107  145526  SISPG189    REL-V3R2M0  5763-PW1
     A                                      KEEP
     A                                      OVERLAY
     A                                      PUTOVR
     A  21N22                               CF05(05 'Refresh')
     A                                      CF12(12 'Previous')
     A                                      WINDOW(6 4 12 70)
     A N20                                  WDWBORDER((*COLOR RED) (*DSPATR RI)-
     A                                       (*CHAR '        '))
     A  20                                  WDWBORDER((*COLOR BLU) (*DSPATR RI)-
     A                                       (*CHAR '        '))
     A                                      USRRSTDSP
     A                                      WDWTITLE((*TEXT &TTL1))
      *N20                                  WDWTITLE((*TEXT &TTL1) (*COLOR WHT))
      * 20                                  WDWTITLE((*TEXT &TTL1) (*COLOR BLU))
     A            TTL1          40A  P
     A            DFSFW          4A  H
     A                                  2  2'Source OUTQ Name . . .'
     A            DFSOQN        10A  B  2 26TEXT('Source OUTQ Name')
     A  21                                  DSPATR(PR)
     A N21                                  DSPATR(UL)
     A  51                                  DSPATR(RI)
     A  51                                  DSPATR(PC)
     A  51                                  COLOR(RED)
     A N51                                  COLOR(GRN)
     A                                      OVRDTA
     A                                      OVRATR
     A                                  3  2'Source OUTQ Library. .'
     A            DFSOQL        10A  B  3 26TEXT('Source OUTQ Library')
     A  21                                  DSPATR(PR)
     A N21                                  DSPATR(UL)
     A  52                                  DSPATR(RI)
     A  52                                  DSPATR(PC)
     A  52                                  COLOR(RED)
     A N52                                  COLOR(GRN)
     A                                      OVRDTA
     A                                      OVRATR
     A                                  4  2'Source OUTQ Text . . .'
     A            DFSOQT        45   B  4 26CHECK(LC)
     A  22                                  DSPATR(PR)
     A N22                                  DSPATR(UL)
     A                                      OVRDTA
     A                                      OVRATR
     A                                  6  2'Target Machine . . . .'
     A            DFTGTM        10A  B  6 26TEXT('Target Machine')
     A  22                                  DSPATR(PR)
     A N22                                  DSPATR(UL)
     A  53                                  DSPATR(RI)
     A  53                                  DSPATR(PC)
     A  53                                  COLOR(RED)
     A N53                                  COLOR(GRN)
     A                                      OVRDTA
     A                                      OVRATR
     A                                  7  2'Target OUTQ Name . . .'
     A            DFTOQN        10A  B  7 26TEXT('Target OUTQ Name')
     A  22                                  DSPATR(PR)
     A N22                                  DSPATR(UL)
     A  54                                  DSPATR(RI)
     A  54                                  DSPATR(PC)
     A  54                                  COLOR(RED)
     A N54                                  COLOR(GRN)
     A                                      OVRDTA
     A                                      OVRATR
     A                                  8  2'Target OUTQ Library. .'
     A            DFTOQL        10A  B  8 26TEXT('Target OUTQ Library')
     A  22                                  DSPATR(PR)
     A N22                                  DSPATR(UL)
     A  55                                  DSPATR(RI)
     A  55                                  DSPATR(PC)
     A  55                                  COLOR(RED)
     A N55                                  COLOR(GRN)
     A                                      OVRDTA
     A                                      OVRATR
      *
     A  21 22N23
     AAN24                              9  2'Enter B=Both OUTQ, S=-
     A                                      Source only, T=Target only. .'
     A                                      DSPATR(HI)
     A                                      OVRATR
     A  21 22N24  DFDELT         1A  B  9 53TEXT('Delete which OUTQ?')
     A                                      VALUES('B' 'S' 'T')
     A                                      DSPATR(HI)
     A       N23                            DSPATR(UL)
     A        23                            DSPATR(ND PR)
     A                                      OVRDTA
     A                                      OVRATR
     A  21 22 23  DFCONF        50A  O  9  2TEXT('Confirmation Message')
     A                                      DSPATR(HI PC)
     A                                      OVRDTA
     A                                      OVRATR
      *
     A  21 22
     AON21N22                          10  2'F3=Exit   F12=Previous'
     A                                      COLOR(BLU)
     A  21N22                          10  2'F3=Exit   F5=Refresh   F12=Previou-
     A                                      s'
     A                                      COLOR(BLU)
      *           BUTTON2        2Y 0B 10  2PSHBTNFLD
      *                                     PSHBTNCHC(1 'Enter')
      *                                     PSHBTNCHC(2 'F3=Exit'      CF03)
      * 21N22                               PSHBTNCHC(3 'F5=Refresh'   CF05)
      *                                     PSHBTNCHC(4 'F12=Previous' CF12)
      *
     A          R MSGRCD2                   SFL
     A                                      SFLMSGRCD(11)
     A            MSGKEY                    SFLMSGKEY
     A            PGMQ##                    SFLPGMQ
     A          R MSGCTL2                   SFLCTL(MSGRCD2)
     A                                      WINDOW(TS0010D2)
     A  21N22                               CF05(05 'Refresh')
     A                                      CF12(12 'Previous')
     A                                      OVERLAY
     A N43                                  SFLDSP
     A N43                                  SFLDSPCTL
     A N43                                  SFLINZ
     A  43                                  SFLCLR
     A  45
     AON45                                  SFLEND
     A                                      SFLSIZ(   2)
     A                                      SFLPAG(   1)
     A            PGMQ##                    SFLPGMQ
